Excel Moyenne pourcentage

Bonjour le forum

=MOYENNE(Janvier:Decembre!N2). Est il possible d'ajouter à cette formule la condition: sauf Si "N2"=0%

Merci d'avance

Nonno

Bonjour

A tester

=SOMME.SI(Janvier:Decembre!N2:N100; "<>0%") / NB.SI(Janvier:Decembre!N2:N100; "<>0%")

Bonsoir joco et merci

Mais ça ne marche pas:

Bonjour à tous,

Avec vos noms de feuilles quelque part, par exemple en A1:A12 (attention aux accents), essayez :

Pour ne prendre que les cellules différentes de 0 (une cellule vide est considérée comme <> de 0) :

=SOMME(Janvier:Decembre!N2)/SOMME(NB.SI(INDIRECT($A$1:$A$12&"!N2");"<>0"))

Pour exclure les cellules égales à 0 et les cellules vides :

=SOMME(Janvier:Decembre!N2)/SOMME(NB.SI.ENS(INDIRECT($A$1:$A$12&"!N2");"<>";INDIRECT($A$1:$A$12&"!N2");"<>0"))

bonsoir Be Good

C tout bon!

Merci encore et bonne soirée

Nonno

Bonsoir à tous !

Une approche directe à tester :

=LET(v; ASSEMB.V(Janvier:Decembre!N2); MOYENNE(FILTRE(v; v <> 0)))

Merci JFL

Bonne journée

Nonno

Bonjour à tous !

Bien...

Je vous remercie de ce retour.

Bonjour le forum

Voilà un code qui m'a été proposé par JFL qui fonctionne parfaitement, mais le fait qu'il ne tienne pas compte de "N2" si égal à 0 me pose des problèmes dans certains de mes calculs. Alors serait il possible d'ignorer seulement "N2" Si inférieur à 0 (donc négatif).

Merci d'avance

Nonno

LET(v; ASSEMB.V(Janvier:Decembre!N2); MOYENNE(FILTRE(v; v <> 0)))

Bonjour à tous !

Pour cette contrainte, je vous propose de tester la formule suivante :

LET(v; ASSEMB.V(Janvier:Decembre!N2); MOYENNE(FILTRE(v; v >= 0)))

Bonjour et merci JFL.

Bonne journée

Cordialement

Nonno