Recherche inversée
Bonjour,
Je suis à la recherche d'une formule genre index/equiv ou RechercheX mais inversée (que je n'arrive pas à mettre en place) pour le tableau en pièce jointe (ou autre solution qui m'échappe 🤔).
J'ai un planning qui comporte des actions, pour lesquelles je fixe une date en choisissant un statut (une seule cellule comportant un statut par ligne, statut qui évolue selon l'avancement).
Je voudrais simplement en colonne C faire une recherche par rapport à chaque ligne de la colonne G à HZ pour venir y mettre la dénomination du statut qui est dans l'onglet "Clés" (exemple pour la ligne 4, je voudrais qu'en cellule C4 soit inscrit " Approuvé/vérifié").
De la même manière je souhaiterai qu'en colonne D vienne se mettre la date qui correspond à celle ou le statut est inscrit sur la ligne concernée (exemple pour la ligne 4, je voudrais qu'en cellule D4 soit inscrit 17/09/2025).
Merci d'avance pour vos réponses.
Bonjour,
C'est parce qu'il faut d'abord filtrer la ligne pour ne récupérer que la cellule remplie, avant de la chercher.
Une formule simple (en C4), en supposant que vous n'avez qu'une seule entrée par ligne.
=RECHERCHEX(
FILTRE(Tableau1[@[16/09/2025]:[01/05/2026]];Tableau1[@[16/09/2025]:[01/05/2026]]<>"");
'Clés '!$B$4:$B$7;'Clés '!$C$4:$C$7)Et une formule un peu plus longue, pour gérer le cas où l'état évolue dans le tableau (on renvoie le dernier état renseigné) :
=RECHERCHEX(
LET(
_cles; FILTRE(Tableau1[@[16/09/2025]:[01/05/2026]]; Tableau1[@[16/09/2025]:[01/05/2026]] <> "");
INDEX(_cles; NBVAL(_cles))
);
'Clés '!$B$4:$B$7;
'Clés '!$C$4:$C$7
)EDIT : je n'avais pas vu la question pour les dates. Meme principe (en D4) :
=FILTRE(Tableau1[[#En-têtes];[16/09/2025]:[01/05/2026]];NON(ESTVIDE(Tableau1[@[16/09/2025]:[01/05/2026]])))ou bien (recommandé)
=LET(_dates;FILTRE(Tableau1[[#En-têtes];[16/09/2025]:[01/05/2026]];NON(ESTVIDE(Tableau1[@[16/09/2025]:[01/05/2026]])));
INDEX(_dates;NBVAL(_dates)))Bonjour
vu qu'il n'y a qu'une seule cellule remplie par ligne
=RECHERCHEX(CONCAT(Tableau1[@[16/09/2025]:[01/05/2026]]);'Clés '!$B$4:$B$7;'Clés '!$C$4:$C$7;"")
pour la date
=RECHERCHEX("*";Tableau1[@[16/09/2025]:[01/05/2026]];Tableau1[[#En-têtes];[16/09/2025]:[01/05/2026]];"";2)
Stéphane
Pour rechercher la dernière occurrence, ajouter un -1 en dernier argument du RECHERCHEX
=RECHERCHEX(
RECHERCHEX("*";Tableau1[@[16/09/2025]:[01/05/2026]];Tableau1[@[16/09/2025]:[01/05/2026]];"";2;-1);
'Clés '!$B$4:$B$7;
'Clés '!$C$4:$C$7;
"")
et pour la dernière date
=RECHERCHEX("*";Tableau1[@[16/09/2025]:[01/05/2026]];Tableau1[[#En-têtes];[16/09/2025]:[01/05/2026]];"";2;-1)
Stéphane
Pour rechercher la dernière occurrence, ajouter un -1 en dernier argument du RECHERCHEX
=RECHERCHEX( RECHERCHEX("*";Tableau1[@[16/09/2025]:[01/05/2026]];Tableau1[@[16/09/2025]:[01/05/2026]];"";2;-1); 'Clés '!$B$4:$B$7; 'Clés '!$C$4:$C$7; "")et pour la dernière date
=RECHERCHEX("*";Tableau1[@[16/09/2025]:[01/05/2026]];Tableau1[[#En-têtes];[16/09/2025]:[01/05/2026]];"";2;-1)Stéphane
Oh, merci pour l'astuce
Merci à tous, rien à dire, tout fonctionne. Je viens d'apprendre une autre approche de rechercheX.
Bonne fin de journée.