TbDateMenu_MouseDown et cbLégumes

Question

A ce stade du programme, est-il normal que le tbDateMenu et le cbLégumes ne se remplissent pas ? D'avance merci pour vos réponses. Date menu : résolu j'avais mis = zéro au lieu de &gt;zéro...

Jean-Paul · Accepted Answer

Petit retour sur le code. Dim Suppr As Boolean Dim Message As Boolean Dim Article As String Dim I As Long Ces variables sont initialisées mais pas utilisées. Au niveau du module préférez Private en lieux et place de Dim. tbDateCréationMenu = Format(Date, "dddddd") End Sub Pour une meilleure compréhension utilisez le format Long date. tbDateCréationMenu = Format(Date, "Long date") End Sub Dans ces lignes : If Cpt &gt; 0 Then ReDim Preserve Résult(1 To Cpt) Select Case NatureMenuAllégéeSel Case Is = "LMMR" cbLégumes.List = Résult End Select End If Que voulez-vous faire avec le Redim Preserve Résult(1 To Cpt) ...

Jean-Paul · Accepted Answer

Re,

Si vous ne savez pas prenez l'habitude de regarder la documentation de Crosoft.

Bon j'ai survolé le code sans approfondir, d'où ma question sur le deuxième Redim Preserve. Donc en fait le tableau est dimensionné sur le nombres de lignes du tableau.

    ReDim Résult(1 To Tbl.Rows.Count)

Puis si la condition est remplie alors on écrit sur les premières lignes du tableaux, grâce au compteur Cpt.

        If Left(Tbl.Cells(I, 4).Value, Nb_NatureMenuAllégéeSel) = NatureMenuAllégéeSel Then
            Cpt = Cpt + 1
            Résult(Cpt) = Tbl.Cells(I, 3).Value
        End If

Enfin on fait un Redim Preserve sur le tableau en fonction de Cpt. Ceci évite d'avoir des entrées vides dans le tableau si Cpt est inférieur au nombre de lignes du tableau.

Bon pour ma part j'aurais redimensionné le tableau au niveau de la condition mais bon, à chacun sa technique.

Du coup dans la procédure cbNatureMenuAllégée_Change la variable Lastrow ne sert à rien.

Qu'apporte Private au lieu de Dim ?

Elles ont la même fonction, c'est juste pour rendre le code plus clair et différencier les variables Modules de celles des procédures.

Jean-Paul · Accepted Answer

La déclaration des variable et un chose très importante et il faut connaitre, non seulement leurs portées, mais aussi l'endroit le plus propice pour leurs déclarations.

Prenez le temps de lire la documentation de Crosoft.

En ce qui me concerne (Et cela n'engage que moi.) Je préfère déclarer les variables (A l'instar de Vb.Net et autres.) au plus près de leurs utilisations.

J'utilise avec parcimonie les variables de niveau Module, je leurs préfère soit des variables de niveau procédures, soit l'utilisation d'arguments pour les procédures et fonctions.

Encore une chose : Call MiseÀJourTitre Il n'est plus nécessaire et utile de mentionner le Call cela date de QuickBasic.

Petit exemple de simplification, DateMenu est déclaré au niveau module, mais vous ne vous en servez que dans la procédure tbDateMenu_MouseDown donc vous pouvez la déclarer au niveau procédure. Voici le code modifié :

Option Explicit
'COMPTABILITÉV2.xltm.

Private Sub cmdRetourFeuilleAccueilAnnuler_Click()
    Unload Me
End Sub

Sub MiseÀJourTitre()
'Va compléter l'Intitulé lbTitre avec le contenu choisi dans la Zone de liste modifiable cbNatureMenu et avec le contenu choisi dans la Zo _
ne de texte tbDateMenu.
    'Me.lbTitre = "Création" & " " & LCase(cbNatureMenuAllégée) & " " & "du " & LCase(tbDateMenu) & "."
End Sub

Private Sub UserForm_Activate()
    cbNatureMenuAllégée.List = Range("TabNatureMenuAllégée").Value
    tbDateCréationMenu = Format(Date, "dddddd")
End Sub

Private Sub cbNatureMenuAllégée_Change()

    tbCodeNatureMenuAllégée.Value = cbNatureMenuAllégée.Column(1)

    Dim NatureMenuAllégéeSel As String
    NatureMenuAllégéeSel = tbCodeNatureMenuAllégée

    Dim Nb_NatureMenuAllégéeSel As Variant
    Nb_NatureMenuAllégéeSel = Len(NatureMenuAllégéeSel)

    Dim Tbl As Range
    Set Tbl = Range("TabLégumesViandesDesserts")

    Dim Résult() As String
    ReDim Résult(1 To Tbl.Rows.Count)
    Dim Cpt As Long
    Cpt = 0

    Dim I As Long
    For I = 1 To Tbl.Rows.Count
        If Left(Tbl.Cells(I, 4).Value, Nb_NatureMenuAllégéeSel) = NatureMenuAllégéeSel Then
            Cpt = Cpt + 1
            Résult(Cpt) = Tbl.Cells(I, 3).Value
        End If
    Next I

    If Cpt > 0 Then
        ReDim Preserve Résult(1 To Cpt)
        Select Case NatureMenuAllégéeSel
            Case Is = "LMMR"
                cbLégumes.List = Résult

        End Select
    End If
    Call MiseÀJourTitre
End Sub

Private Sub tbDateMenu_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
    Dim DateMenu As Date
    DateMenu = Calendrier.Choix(tbDateMenu)
        If DateMenu > 0 Then tbDateMenu = Format(DateMenu, "dddddd")
    Call MiseÀJourTitre
End Sub

Et pour finir.

Apprenez à être plus strict, VBA est complaisant, mais il ne faut pas trop en abuser. Exemple :

Sur votre formulaire cbNatureMenuAllégée est paramétré avec une colonne et renvoie la valeur de la colonne 1 (Jusque là c'est classique)

Ensuite vous charger sa liste, et vous vous retrouvez avec deux colonnes, et vous utilisez la propriété Column pour renvoyer le résultat.

Je vous conseille si vous devez toujours récupérer la valeur de la colonne 1 de la définir par défaut à l'initialisation du formulaire :

Private Sub UserForm_Activate()
    With cbNatureMenuAllégée
        .ColumnCount = 2
        .BoundColumn = 2
        .ColumnWidths ";0pt)"
        .List = sh02.Range("TabNatureMenuAllégée").Value
    End With
    tbDateCréationMenu = Format(Date, "dddddd")
End Sub

Ensuite il ne vous reste plus qu'a lire la valeur de la propriété Value.

Jean-Paul · Accepted Answer

Oui évidemment je suis aller trop vite en tapant le code, mais ce genre d'erreur devrait vous sauter aux yeux, non ? Je le dis toujours et je le répète encore, faire du copier coller ne vous apporte rien de bon, le but et que vous tapiez l'intégralité du code, il n'y que comme cela que vous le retiendrez. ColumnWidths attends une chaine de caractère qui représente les longueurs de chaque colonnes, si la longueur n'est pas définie alors c'est la longueur par défaut qui est prise en compte. La longueur est définie en points "10pt" , ou "50pt;0pt" ou "0pt;10pt;70pt;0pt" regarder les lignes du dessus et vous trouverez une des deux erreurs...

Jean-Paul · Accepted Answer

Voilà vous avez trouvé les deux erreurs.... Bien.

une nouvelle erreur surgit dans la procédure Private Sub cbNatureMenuAllégée_Change

Bon je vais prendre ma boule de cristal, et je vais regarder de ce pas...

Il faudrait aussi savoir ce que vous voulez faire dans cette procédure...