Toujours le même N°en bas du tirage au sort

Bonjour

Avec ce code je fais du tirage au sort il fonctionne bien.

Par contre pouvez vous svp me dire pourquoi le dernier numéro qui s'affiche en bas de colonne est toujours le 28

Je vous remercie

Sub MelangerEtColler()
    Dim i As Integer, j As Integer
    Dim numArray(2 To 29) As Variant
    Dim rng As Range
    Dim temp As Variant
    Dim ws As Worksheet

    ' Définir la feuille de travail
    Set ws = ThisWorkbook.Sheets("Feuil1") 

    ' Lire les numéros de la colonne A dans un tableau
    For i = 2 To 29
        numArray(i) = ws.Cells(i, 1).Value
    Next i

    ' Mélanger et coller dans les colonnes B à Q
    For j = 3 To 17
    ' Colonnes B à Q
        ' Mélanger le tableau
        For i = 2 To 29
            Dim randomIndex As Integer
            randomIndex = Int((28 - i + 1) * Rnd + i) ' Générer un index aléatoire
            ' Échanger les éléments
            temp = numArray(i)
            numArray(i) = numArray(randomIndex)
            numArray(randomIndex) = temp
        Next i

        ' Coller les numéros mélangés dans la colonne j
        For i = 2 To 29
            ws.Cells(i, j).Value = numArray(i)
        Next i
    Next j

    MsgBox "Mélange et collage terminés !"
End Sub

Je joins une photo du tableau de tirage

Résolu il faut modifier ce morceau de

Dim randomIndex As Integer
            randomIndex = Int((28 - i + 1) * Rnd + i) ' Générer un index aléatoire

code mettre un 2 au lieu de 1

Bonjour,

je situerai votre problème plutôt ici:

 randomIndex = Int((28 - i + 1) * Rnd + i) ' Générer un index aléatoire

car, lorsque i=2, nous avons: 28 - 2 +1= 27, il faudrait remplacer 28 par 29

 randomIndex = Int((29 - i + 1) * Rnd + i) ' Générer un index aléatoire

Cdlt