Formule de feuille à feuille
Bonjour,
Nouveau sur ce forum, je suis ravi qu'il existe et je pense que ça va devenir mon ami https://forum.excel-pratique.com/template/img/emojis/1f603.svg)">
J'essai de créer un tableau avec des renvoies d'une feuille à l'autre mais à l'heure je n'ai pas trouvé la bonne formule.
je vais essayé d'être assez clair :
sur la feuille Com JG :
- j'ai des colonnes L P S V Z et AC qui contient des dates
- j'ai des colonnes M Q T W AA et AD qui contient des montants en €
Chaque colonne marche en relation ensemble c'est à dire que L correspondant à la date de facturation et M correspond au montant à facturer qui ne s'affiche qu'après avoir mis "oui" dans la colonne K avec la formule suivante : =SI(K4="oui"; I4*30%; 0)
sur la feuille 4 :
- la ligne 1 correspond au mois de l'année B1 JANVIER, C1 FEVRIER, etc
- la colonne A correspond au jour du mois A2 le 1er, A3 le 2, etc
mon objectif c'est de faire apparaitre le chiffre d'affaire mensuel lorsque je renseigne la feuille Com JG de la manière suivante :
- je renseigne la colonne K en y mettant "oui"
- je renseigne la colonne L en y mettant la date du jour (ex 05/05/2025)
- la colonne M se renseigne toute seul (formule ci dessus) (ex 2313,78€)
ce qui doit apparaitre sur la feuille 4 :
- le montant de la colonne M de la feuille Com JG (ex 2313,78€) doit s'afficher en F6 et s'il y a d'autres montants à la même date dans les autres colonnes L P S V Z AC, les montants des colonnes M Q T W AA AD s'additionne
voici la formule que j'ai récupéré mais en vain ça ne fonctionne pas :
=SOMMEPROD( ((('Com JG'!L6:L1004=DATE(2025;5;1))*('Com JG'!M6:M1004)) + (('Com JG'!P6:P1004=DATE(2025;5;1))*('Com JG'!Q6:Q1004)) + (('Com JG'!S6:S1004=DATE(2025;5;1))*('Com JG'!T6:T1004)) + (('Com JG'!V6:V1004=DATE(2025;5;1))*('Com JG'!W6:W1004)) + (('Com JG'!Z6:Z1004=DATE(2025;5;1))*('Com JG'!AA6:AA1004)) + (('Com JG'!AC6:AC1004=DATE(2025;5;1))*('Com JG'!AD6:AD1004)) ))
si vous pouvez m'aider je vous en serai très reconnaissant.
Merci d'avance
Bonjour et bienvenue sur ce forum
Votre demande concerne Excel ou Google Sheet comme mentionné dans votre profil ?
Pensez à mettre un fichier sans données confidentielles, ce sera plus facile de comprendre et vous apporter une solution
Cordialement
Bonjour,
Le mieux est quand même d'utiliser "Somme.si" à la place de "Sommeprod", moins gourmand en ressources.
Cdlt
bonjour
en effet c'est Excel et non Google Sheet.
et merci pour Arturo83 malheureusement je n'ai pas assez de recule pour connaitre les différences entre les formules, as tu des idées pour mettre la bonne formule ?
voici le tableau en question
Pourquoi ne déposez-vous pas un fichier (en prenant soin de supprimer les données confidentielles), on perd plus de temps à en créer un qui ressemble à votre description que de vous fournir une réponse?
Voici le fichier
Bonjour à tous,
Joalfrite83, avec un TS (Tableau structuré pour vos dossiers) et des SOMME.SI() tout simple
Je pense même qu'on peut faire une requête PQ (Power Query)
A+
bonjour JExceL2fr,
merci beaucoup pour cette aide et d'avoir recustomisé le tableau.
par contre dans la feuille Com JG si je rajoute les formules :
- je renseigne la colonne K en y mettant "oui"
- je renseigne la colonne L en y mettant la date du jour (ex 05/05/2025)
- la colonne M se renseigne toute seul =SI(K4="oui"; I4*30%; 0) (ex 2313,78€)
est ce que ça ne va pas fausser la feuille4 ?
j'ai copié collé tes formules de la feuille4 remixé mais ça m'affiche :
Bonjour,
Voici 2 propositions
-la première avec le tableau de la feuille "Com JG" converti en tableau structuré.
-la deuxième avec le tableau standard:
Je vous ai mis la deuxième proposition au cas où, vous ne maîtriseriez pas trop les formules avec un tableau structuré
exemple de formule en B2 de la feuille 4
en tableau standard:
=SOMME.SI('Com JG'!$L$3:$L$14;DATE($A$1;COLONNE()-1;$A2);'Com JG'!$M$3:$M$14)+
SOMME.SI('Com JG'!$P$3:$P$14;DATE($A$1;COLONNE()-1;$A2);'Com JG'!$Q$3:$Q$14)+
SOMME.SI('Com JG'!$S$3:$S$14;DATE($A$1;COLONNE()-1;$A2);'Com JG'!$T$3:$T$14)+
SOMME.SI('Com JG'!$V$3:$V$14;DATE($A$1;COLONNE()-1;$A2);'Com JG'!$W$3:$W$14)+
SOMME.SI('Com JG'!$Z$3:$Z$14;DATE($A$1;COLONNE()-1;$A2);'Com JG'!$AA$3:$AA$14)+
SOMME.SI('Com JG'!$AC$3:$AC$14;DATE($A$1;COLONNE()-1;$A2);'Com JG'!$AD$3:$AD$14)la même avec le tableau structuré:
=SOMME.SI(Tabl1[[Date 1er acompte facturé]:[Date 1er acompte facturé]];DATE($A$1;COLONNE()-1;$A2);Tabl1[[30% 1er acompte]:[30% 1er acompte]])+
SOMME.SI(Tabl1[[Date 2ème situation facturé]:[Date 2ème situation facturé]];DATE($A$1;COLONNE()-1;$A2);Tabl1[[40% 2ème situation]:[40% 2ème situation]])+
SOMME.SI(Tabl1[[Date 3ème situation facturé]:[Date 3ème situation facturé]];DATE($A$1;COLONNE()-1;$A2);Tabl1[[20% situation]:[20% situation]])+
SOMME.SI(Tabl1[[Date situation prédéfini facturé]:[Date situation prédéfini facturé]];DATE($A$1;COLONNE()-1;$A2);Tabl1[[x% situation]:[x% situation]])+
SOMME.SI(Tabl1[[Date dernière situation facturé]:[Date dernière situation facturé]];DATE($A$1;COLONNE()-1;$A2);Tabl1[[10% dernier acompte]:[10% dernier acompte]])+
SOMME.SI(Tabl1[[Date supplément facturé]:[Date supplément facturé]];DATE($A$1;COLONNE()-1;$A2);Tabl1[[Supplément]:[Supplément]])on voit tout de suite que c'est moins clair, en revanche, le gros avantage du tableau structuré est que, une fois que la formule est écrite, on ne touche plus à rien, même si le tableau de la feuille "Com JG" s'étire vers le bas, les formules s'adapteront automatiquement, ce qui n'est pas le cas du tableau standard.
Petite explication complémentaire, la répétition de certains éléments entre crochets et séparés par ":" dans la formule d'un tableau structuré est l'équivalent du "$" pour figer une ligne ou une colonne, exemple:
Tabl1[[Date 1er acompte facturé]:[Date 1er acompte facturé]]correspond à la colonne figée L qui s'écrit: "$L" dans une formule standard.
Cdlt
Si les solutions vous conviennent, veuillez passer le sujet en "RESOLU", merci.
Merci beaucoup Arturo 83 tout fonctionne à merveille
par contre je n'ai pas trouvé comment faire pour passer le sujet en résolu ?
bonsoir,
par contre je n'ai pas trouvé comment faire pour passer le sujet en résolu ?
voici
bouton que tu trouves en haut à droite de chaque réponse.