Cacher des feuilles

Question

Je me heurte à un tout petit problème.
Je voudrais qu'en ouvrant un fichier qui contient plusieurs feuilles, ne l'ouvrir qu'en faisant apparaitre qu'une seule feuille parmi toutes celles qu'il contient
Pour cela j'ai créé un Userform contenant un Combobox dans lequel on retrouve toutes les feuilles et en choississant la feuille qui me convient, suite à un click sur le combobox, je voudrais que le le fichier s'ouvre en ne laissant apparaitre que la feuille choisie.
Je dois me planter car je n'y arrive pas

saboh12617 · Accepted Answer

Dans ce cas, remplace le code de masquage des feuilles lors de l'ouverture avec le test dont je parlais : (tu remarqueras que j'ai déplacé l'affichage de ta feuille en 1e ligne, car si par hasard elle est invisible alors le code risque de planter en voulant masquer les autres. C'est ce qui arrivait avec ton code, et donc la dernière feuille restait visible) Private Sub Workbook_Open() Worksheets("Liste").Visible = True Dim sht As Object ' on masque toutes les feuilles sauf la feuille liste For Each sht In ThisWorkbook.Sheets If sht.Name &lt;&gt; "Liste" Then sht.Visible = False Next sht ' on affiche l'UF UserForm2.Show End Sub Que tu peux aussi écrire comme ceci, ce qui t'assure d'afficher la feuille Liste si par hasard elle est masquée. C'est + court. Private Sub Workbook_Open() Dim sht As Object ' on masque toutes les feuilles sauf la feuille Liste For Each sht In ThisWorkbook.Sheets sht.Visible = (sht.Name &lt;&gt; "Liste") Next sht ' on affiche l'UF UserForm2.Show End Sub...

saboh12617 · Answer

Salut @Jacky,

Je procèderai comme suit :

Lors de l'ouverture du classeur (Workbook.Open) : masquer toutes les feuilles

Ouvrir l'UF de sélection de feuilles

Lors de la fermeture de l'UF, afficher les feuilles checkées via combobox.

Ci-joint un petit exemple qui s'adapte automatiquement au nombre de feuilles du classeur. On essaie d'éviter au maximum les erreurs de saisie.

11affichage-feuilles.xlsm (29.54 Ko)

Ci-après le code en question : (EDIT : code + fichier MAJ pour corriger petit bug)

' ========================= Code Workbook
Option Explicit

Private Sub Workbook_Open()
  ' on doit laisser au moins 1 feuille visible : on en ajoute 1 temporaire a la fin
  With ThisWorkbook.Worksheets
    Set tempSht = .Add(, .Item(.Count))
  End With

  ' on masque toutes les feuilles sauf la derniere
  Dim sht As Object
  On Error Resume Next
  For Each sht In ThisWorkbook.Sheets
    sht.Visible = False
  Next sht
  On Error GoTo 0

  ' on affiche l'UF
  With New UserForm1
    .Show
  End With
End Sub

' ========================= Code Module1 (sub optionnel, juste pour tester)
Option Explicit

Public tempSht As Worksheet

' ========================= Code Userform
Option Explicit

Private Sub UserForm_Initialize()
  Dim sht As Object, lastCtrl As MSForms.Control
  Dim i As Long
  For i = 1 To ThisWorkbook.Sheets.Count - 1
    Set sht = ThisWorkbook.Sheets(i)
    Set lastCtrl = Me.Controls.Item(Me.Controls.Count - 1)
    With Me.Controls.Add("Forms.CheckBox.1")
      .Caption = sht.Name
      .Top = lastCtrl.Top + lastCtrl.Height
    End With
  Next i
End Sub

Private Sub btnConfirm_Click()
  ' on vérifie que au moins 1 feuille est cochée
  Dim ctrl As MSForms.Control, selectionValide As Boolean
  For Each ctrl In Me.Controls
    If TypeOf ctrl Is MSForms.CheckBox Then
      selectionValide = ctrl.Value Or selectionValide
    End If
  Next ctrl

  If Not selectionValide Then
    ' on ne ferme pas l'UF
    MsgBox "Veuillez sélectionner au moins 1 feuille !", vbCritical + vbOKOnly
  Else
    ' si valide, on ferme l'UF
    Unload Me
  End If
End Sub

Private Sub UserForm_Terminate()
  Dim ctrl As MSForms.Control
  For Each ctrl In Me.Controls
    If TypeOf ctrl Is MSForms.CheckBox Then
      ThisWorkbook.Sheets(ctrl.Caption).Visible = ctrl.Value
    End If
  Next ctrl

  ' suppression de la feuille temporaire
  Application.DisplayAlerts = False
  tempSht.Delete
  Application.DisplayAlerts = True
End Sub

Dan · Answer

De mon coté je préfère toujours les masquer à la fermeture que des fois un gars n'activerait pas les macros dans le fichier. Voyez aussi ce lien --&gt; https://excel-pratique.com/fr/astuces_vba/forcer_activation_des_macros Cordialement...

saboh12617 · Answer

Le point clé : à tout moment, tu dois toujours avoir AU MOINS 1 FEUILLE VISIBLE.

Tu dois donc t'assurer que tu ne masques pas "la dernière feuille visible", sinon ça plante. Pour ma part j'ai contourné en ajoutant une feuille temporaire à la fin du classeur, et en la supprimant lors de la fermeture de l'UF. De plus, pour me simplifier la vie, j'ai mis "On Error Resume Next" lors du masquage des feuilles. Vu que les feuilles sont masquées dans l'ordre, elles sont toutes masquées SAUF celle qui fait erreur = la dernière = ma feuille temporaire.

Autrement toi tu as peut-être une feuille de sommaire, tu peux faire un test pour t'assurer de la garder visible (de type si le nom de la feuille = "sommaire", alors ne pas la masquer).

Dan · Answer

@saboh12617 :

Ma question peut paraître bizarre mais pourquoi With New Userform1 dans le code de l'ouverture ?
C'est l'IA qui donne çà ?

J'aurais fait simplement ceci --> Userform1.show

Il y a peut-être une raison ?

saboh12617 · Answer

Non non c'est voulu, bonne lecture UserForm1.Show – Rubberduck News Cependant oui, dans le cas et l'usage présent, Userform1.Show est parfaitement équivalent. Disons que c'est une habitude de "bonne pratique"...

Dan · Answer

Ok merci. Je vais lire cela mais hormis les modules de classe, je n'ai jamais vu cette façon même dans les livres VBA de Walkenbach ou autres Crdlt Edit : A titre d'un autre exemple un fichier réalisé par Feu Th. Pourtier en 2004 (pouf c'est loin tout cela ...) et qui me semble aussi rejoindre la demande de Jacky...

saboh12617 · Answer

Oui désolé j'aurai dû le mettre dans mon 1e message. Pour être tout à fait honnête j'avais oublié ce détail et c'est en testant que je m'en suis rendu compte 😉. Content d'aider, bonne fin de journée et bon weekend ...

Dan · Answer

Re @Jacky : merci de penser à cloturer ce fil et d'autres fils toujours ouverts visibles ici --&gt; https://forum.excel-pratique.com/membre/68866 Cordialement...