Filtrer un tableau avec des critères sous la forme d'un autre tableau

Bonjour,

Je me permet d'ouvrir ce sujet car j'essai de filtrer un tableau (qui contient des noms de communes) avec plusieurs critères qui sont sous la forme d'une colonne dans un autre onglet.

Je sais utiliser

"Sheets("BDD").Range("$B$7:$AO$20000").AutoFilter Field:=7, Criteria1:=Array("ma ville", "ma ville 2", "ma ville 3"), Operator:=xlFilterValues"

Mais ce que je cherche à obtenir serait de l'ordre de :

Sheets("BDD").Range("$B$7:$AO$20000").AutoFilter Field:=7, Criteria1:=Array(TABLEAU_CRITERES), Operator:=xlFilterValues

ou

Sheets("BDD").Range("$B$7:$AO$20000").AutoFilter Field:=7, Criteria1:=Array(Sheets("CRITERE").Range("A2:$A30")), Operator:=xlFilterValues

Je cherche donc à utiliser un autre tableau comme critère (qui est une liste de commune) mais je n'y arrive pas (je bricole en VBA)

Je vous remercie par avance pour votre aide

Bonjour Leb95, le forum,

A tester...dommage que tu n’aies pas joint un fichier représentatif....

Option Explicit

Sub filtre()
 Dim Mondico As Object
 Dim i&

  Set Mondico = CreateObject("Scripting.dictionary")

   With Sheets("CRITERE")
    For i = 2 To .Range("A" & Rows.Count).End(xlUp).Row
      Mondico(.Range("A" & i).Value) = ""
    Next i
   End With

   With Sheets("BDD")
    .Range("$B$7:$AO$20000").AutoFilter
    .Range("$B$7:$AO$20000").AutoFilter Field:=7, Criteria1:=Mondico.keys, Operator:=xlFilterValues
   End With
End Sub

Cordialement,

Je vous remercie ! je vais tester votre proposition !

(si je n'y arrive pas, je vais faire un fichier "épuré" car j'ai beaucoup de données sensibles sur mon tableau)

Ca fonctionne du tonnerre, pour le moment je ne comprend pas tout mais je vais apprendre !

Encore merci