Fonction pour gérer les dates

Bonjour,

j'ai un tableau avec des dates d'expédition que je souhaite "classer" par quarter.

en gros : si la date est comprise entre le 1/01 et le 31/03 = Q1-2025

Si la date est comprise entre les 01/04 et le 30/06 = Q2-2025

.....

je connais la fonction SI mais pour une condition. Pouvez-vous m'aider svp ?

merci

Bonjour,

Le trimestre peut être obtenu en faisant :

=ARRONDI.SUP(MOIS(TaDate)/3;0)

et l'année en faisant :

= ANNEE(TaDate)

Tu rajoutes ces deux informations dans ton tableau qui sera ensuite classé par trimestre

Notes que ça revient à classer par date donc ça n'a aucun interêt si tu ne fais pas de regroupement.

Bonus si tu veux faire des agrégations utilises un TCD et affiche ta date dans Ligne, clique ensuite droit sur cette donnée et fais grouper par année et trimestre, ça fera le job.

Salut,

Si tu preferes les SI, voici

SI(ET(MOIS(A2)>0;MOIS(A2)<4);"Q1-"&ANNEE(A2);SI(ET(MOIS(A2)>3;MOIS(A2)<7);"Q2-"&ANNEE(A2); SI(ET(MOIS(A2)>6;MOIS(A2)<10);"Q3-"&ANNEE(A2);SI(ET(MOIS(A2)>9;MOIS(A2)<=12);"Q4-"&ANNEE(A2)))))

Si les dates sont en colonne A

Cdlt

Bonjour,

Merci beaucoup pour vos réponses. N'étant pas experte avec EXCEL et je ne sais pas faire et gérer un TCD :(

Dans mon tableau test j'ai 4 colonnes principales (N° projet - Client - Date d'expédition - Quarter) et d'autres colonnes avec d'autres infos après.

je rempli mon tableau au fur à mesure de l'arrivée des projets, ce tableau me sert principalement à voir mes projets par quarter.

WonderAleph : j'ai mis votre formule dans une cellulle mais j'obtient la date du 01/01/1900 et si je rajoute = ANNEE(date) j'obtiens "FAUX.

la formule que j'ai mis : =ARRONDI.SUP(MOIS(G11)/3;0)=ANNEE(G11). Pouvez-vous m'expliquer ce que j'ai mal fait svp?

fg2b : je n'ai pas tout compris à la formule avec des si que vous m'avez proposé mais elle fonctionne :):),

je vous remercie

Cdlt

Bonjour à tous !

Une autre approche ?

Pour une date en A2 :

="Q"&EQUIV(MOIS(A2);{0.4.7.10};1)&TEXTE(A2;"-aaaa")

Bonjour tout le monde,

@fg2b

fg2b a écrit :

SI(ET(MOIS(A2)>0;MOIS(A2)<4);"Q1-"&ANNEE(A2);SI(ET(MOIS(A2)>3;MOIS(A2)<7);"Q2-"&ANNEE(A2); SI(ET(MOIS(A2)>6;MOIS(A2)<10);"Q3-"&ANNEE(A2);SI(ET(MOIS(A2)>9;MOIS(A2)<=12);"Q4-"&ANNEE(A2)))))

Je n'ai jamais été matheux. Sachant que je ne voyais pas l'intérêt d'aller faire des calculs dont je me fichais, je n'ai jamais trop compris pourquoi aller factoriser (ou juste améliorer) certains calculs. Assez étrangement, j'arrive plutôt bien à le trouver sur Excel, cet intérêt.

Quand tu te rends compte que dans tous les arguments de ta fonction tu mets &annee(A2), alors tu peux ne le mettre qu'une seule fois, en dehors de ta fonction.
De même, vois la logique de la fonction suivante qui fait exactement la même chose que ta proposition. Et que les Dieux de la simplification soient avec toi à l'avenir.
La proposition de JFL est mieux, mais c'est surtout pour la logique du SI que je me permets de te dire tout ceci.

="Q"&SI(MOIS(A2)<4;"1-";SI(MOIS(A2)<7;"2-";SI(MOIS(A2)<10;"3-";"4-")))&ANNEE(A2)

@JFL, toujours aussi élégant. Je ne m'en lasse pas

Bonjour,

Merci beaucoup ça fonctionne aussi avec la formule de JFL ça va grandement m'aider.

Bonne journée,

Cdlt

Bonjour à tous de nouveau !

@21Formatic :

Bien....

Je vous remercie de ce retour.

-----> Ne pas oublier de passer le sujet en mode résolu !

tu n'avais rien fais de mal, tu as juste oublié de mettre le format de ta colonne de réponse en standard :/

bon ceci dit tu as trouvé une formule qui convient

Bonjour , merci WonderAleph je note tout de même cette information

Bonne journée