Pour les "pro" des formules
Bonjour,
Voila mon problème. J'ai une formule toute simple "somme(E4:E16)/1000*29" que je voudrai faire glisser pour qu'elle se calcule tous les mois. Seulement la base de ma somme se décale de 5 colonnes et si je tire la formule vers le bas elle devient : "SOMME(E5:E17)/1000*29" alors que je voudrais "SOMME(J4:J16)/1000*29". Comment lui dire de se décaller la somme de 5 colonnes.
Si vous voulez plus d'explications je peux vous envoyer par mail mon tableau, je n'ai pas réussi a le joinde à ce message.
Merci
Bonjour,
=SOMME(DECALER(E$4:E$16;;(LIGNE(A1)-1)*5))/1000*29A+
Merci pour cette réponse, la formule fonctionne. Par contre pouvez vous m'expliquer la formule pour que je puisse l'adapter à mes autres tableaux.
Pourquoi mettre $ entre E et 4 ?
Pourquoi ligne (A1)-1 ?
Merci
Re,
=SOMME(DECALER(E$4:E$16;;(LIGNE(A1)-1)*5))/1000*29
DECALER(Base;lignes;colonnes;[hauteur];[largeur]) renvoie une plage décalée par rapport à la "Base" de x lignes et y colonnes et d'une hauteur et largeur correspondante aux arguments de la fonction.
Les 2 derniers arguments sont facultatifs.
Exemple :
DECALER(A1;2;1) renvoie le contenu de la cellule B3 (2 lignes en dessous et 1 colonne à droite de A1)
LIGNE(A1) renvoie le numéro de ligne correspondant à la cellule A1 (soit 1).
(LIGNE(A1)-1)*5=(1-1)*5=0
Donc DECALER(E$4:E$16;;0) renvoie donc la plage E4:E16.
Quand tu vas recopier la formule sur la ligne suivante, la formule deviendra :
=DECALER(E$4:E$16;;(LIGNE(A2)-1)*5)
La base ne change pas car les lignes sont en référence absolue : grace au $ devant le numéro de ligne.
(c'était ta première question).
LIGNE(A2)=2 donc
DECALER(E$4:E$16;;(LIGNE(A2)-1)*5) → DECALER(E$4:E$16;;(2-1)*5)) → DECALER(E$4:E$16;;5)
décale la plage E4:E16 de 5 colonnes vers la droite.
Dans la cellule suivante, on aura LIGNE(A3) donc le décalage sera de (3-1)*5=10 colonnes vers la droite.
Voilà pour ton autre question.
A+
Merci beaucoup pour vos réponses, elles me seront très utile pour la suite.