Cherche formule SI

Bonjour,

Je cherche la formule me permettant de comptabiliser les ( AY les AZ, les BY, le BZ ... etc) et de renseigner le tableau du bas

Je pense que chaque cellule '?' que je souhaite renseigner aura une formule différente.

Merci beaucoup.

Bonjour et bienvenue,

Si les valeurs sont en A1:B7, la formule unique suivante renvoie le tableau des résultats de manière dynamique

=EXCLURE(GROUPER.PAR(A1:B7;A1:B7;NBVAL);;-1)

EDIT : voir formule @JFL (fonctionnement identique mais plus courte)

Salut Stephgre,

J'aurai fait de la manière suivante :

Sur ton premier tableau, j'aurai créé une autre colonne pour avoir AY BZ, etc.. Tu peux faire de la manière suivante "= A1&B1"

Ensuite, j'aurai fait la formule Nb.Si avec la plage de critere la nouvelle colonne créée et le critère AY ou AZ etc..

Cordialement

Théo

Re,

Pour obtenir exactement le résultat voulu, on peut utiliser la formule suivante (un peu plus complexe)

=LET(tblI;A1:B10;
tblUq;TRIER(UNIQUE(tblI);{1;2});
MAKEARRAY(LIGNES(tblUq);3;
  LAMBDA(r;c;
  SI.MULTIPLE(c;
  1;SI.CONDITIONS(r=1;INDEX(tblUq;r;1);VRAI;SI(INDEX(tblUq;r-1;1)=INDEX(tblUq;r;1);"";INDEX(tblUq;r;1)));
  2;INDEX(tblUq;r;2);
  3;SOMMEPROD(1*(CHOISIRCOLS(tblI;1)=INDEX(tblUq;r;1))*((CHOISIRCOLS(tblI;2)=INDEX(tblUq;r;2))))
  ))
))

Il suffit de modifier la plage A1:B10 en haut de la formule pour correspondre à la plage réelle.

Bonjour et merci de vos réponses, je n'ai peut être pas bien expliqué ce que je souhaite faire :)

Le tableau du haut est rempli et modifié chaque mois.

Et dans celui du bas j'ai besoin d'avoir les informations du nombre de lundi fait par l'équipe 1, de lundi fait par l'équipe 2 etc ..

Merci beaucoup pour vos réponses

Re,

Pouvez-vous prendre le temps de copier-coller la formule ? C'est ce qu'elle renvoit. De manière dynamique et autonome.

Si vous tenez vraiment à travailler de manière inefficace, mettez cette formule dans votre "?"

=SOMMEPROD(1*($A$1:$A$9=A11)*($B$1:$B$9=B11))

Avec encore une fois A1:B9 votre plage initiale, et, en se basant sur le dernier screenshot, A11 et B11 les cellules à comparer dans ce tableau. Ensuite étirez vers le bas.

Bonjour à tous !

Une proposition, type formule unique dynamique, avec un zeste de MFC :

=GROUPER.PAR(A3:B11;B3:B11;NBVAL;;0)

ahhhh... Les formules sont mal traduites. Okok, j'essaie de corriger mes messages.

Re,

Merci beaucoup, Ca fonctionne parfaitement

Très bonne journée

Bonjour à tous de nouveau !

Bien....

Je vous remercie de ce retour.

====> Ne pas oublier de passer le sujet en mode résolu !