Restituer une thematique globale a partir d'une chaine de caractere

Bonjour la communauté,

EXCEL : Par rapport à une colonne texte comprenant plusieurs mots et chiffres, je souhaiterais restituer dans une nouvelle colonne une catégorie liée que j'ai cartographiée dans un autre tableau.

Par ex. :

- CB SNCF Paris 17/12/24 ==> SNCF est reconnu ==> et la colonne restitue TRANSPORT

- PRLV EDF ==> EDF est reconnu ==> la nouvelle colonne restitue ENERGIE

- VIR SEPA REGIE MANTES ==> REGIE est reconnu ==> la nouvelle colonne restitue ADMINISTRATION

- CB TRANSAVIA 20241006 ==> TRANSAVIA est reconnu ==> la nouvelle colonne restitue AVION

- REM CHEQUE ==> CHEQUE est reconnu ==> la nouvelle colonne restitue CHEQUE

- CB WINAMAX ==> WINAMAX est reconnu ==> la nouvelle colonne restitue JEU

En PJ : la 1ère colonne représente le type de donnée à traiter et le tableau la cartographie dédiée.

Merci d'avance pour votre aide!

PS : je me débrouille mais ne suis pas experte, alors j'apprécie les explications, comment dire...., à mon niveau ?

Moebius JS.

Bonjour à tous !

Et....

Une proposition (liée à ma compréhension du besoin...), type formule unique dynamique, en B2 :

=MAP(
    A2:A1550;
    LAMBDA(x;
        LET(
            s; FRACTIONNER.TEXTE(x; ; " ");
            r; RECHERCHEX(s; Tableau1[therme]; Tableau1[typo 2]; "");
            TABLEAU.EN.TEXTE(FILTRE(r; r <> ""; ""))
        )
    )
)

bonjour JFL,

Merci, cela fonctionne mais j'ai besoin d'exploiter les données sous format tableau non en texte.

Bonjour à tous !

Simple adaptation de la formule.....

=LET(
    s; FRACTIONNER.TEXTE(A2; ; " ");
    r; RECHERCHEX(s; Tableau1[therme]; Tableau1[typo 2]; "");
    TABLEAU.EN.TEXTE(FILTRE(r; r <> ""; ""))
)

MERCI !!!

Bonjour à tous de nouveau !

Bien....

Je vous remercie de ce retour.

----> Ne pas oublier de passer le sujet en mode résolu !

bonjour

une contribution " à l'ancienne" ,,, mais ça ne marche pas systématiquement (question de critère)