Recherche Like avec et dans une variable

Bonjour à tous

après un double click sur une cellule (texte) feuille COMF FORM , je souhaite rechercher la valeur trouvée dans la colonne A de la feuille ANALYTIQUE qui CONTIENT le texte, pour copier les lignes concernées par la valeur trouvée.

je vous joint un fichier qui fonctionne quand la recherche est en DUR dans le programme.

Pouvez vous m'aider.

Merci d'avance

Alain

Bonjour,

Votre profil devrait être mise à jour ou vous avez excel 97 ou 2003... ??

Si je double clic sur A7, vous voulez récupérer les lignes 66 à 68 de la feuille analytique et les placer en colonne N et suivante de la feuille Com Form ?

Bonjour

Si je double clic sur A7, vous voulez récupérer les lignes 66 à 68 de la feuille analytique et les placer en colonne N et suivante de la feuille Com Form ?

Oui complétement .

Je vais mettre mon profil a jour avec office 365

Cordialement

Re

Dans la feuille Com Formation, remplacez votre code par celui ci-dessous

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim c As Range, plage As Range
Dim ligA As Byte, ligC As Byte

Set plage = Range("A7:A20") 'définit la plage
If Not Intersect(Target, plage) Is Nothing Then 'condition si la cellule double cliquée est dans la variable plage
    Range("N:Q").ClearContents 'effacer les donnees des colonnes N a Q
    Cancel = False
    With Sheets("ANALYTIQUE")
        ' recherche de la valeur de la cellule cliquee entre ligne 11 et 139 dans colonne A feuille Analytique
        Set c = .Range("A11:A139").Find(Target, LookIn:=xlValues, lookat:=xlPart)
        ligC = Target.Row 'définir variable reprenant la référence de la ligne où le double click a été fait
        If Not c Is Nothing Then 'condition si la variable c a une valeur
            ligA = c.Row + 1 'définir variable pour ligne la variable c à laquelle on ajoute 1 pour commencer la ligne en dessous
            Do 'boucle
                If .Range("A" & ligA) Like "*Total*" Then Cancel = True: Exit Sub 'si on trouve total on arrête le code

                Cells(ligC, 14) = .Cells(ligA, 1)
                Cells(ligC, 15) = .Cells(ligA, 2)
                Cells(ligC, 16) = .Cells(ligA, 3)
                Cells(ligC, 17) = .Cells(ligA, 4)
                ligC = ligC + 1
                ligA = ligA + 1
            Loop
        End If
    End With
Else
    MsgBox "Votre sélection n'est pas dans plage requise", vbInformation, "HORS ZONE"
End If
Cancel = True 'pour ignorer le second clic fait par l'utilisateur lors du double clic
End Sub

Si ok et terminé pensé à cloturer le fil

Cordialement

Merci DAN, cela répond à mon besoins

à 75 ans il est parfois difficile de tout comprendre à la lecture, mais je vais reprendre ligne par ligne pour apprendre encore.

Cordialement

Re

Parfait que cela vous convienne

à 75 ans il est parfois difficile de tout comprendre à la lecture,

Pas de soucis.... je ne suis pas loin de votre age..
Si vous voulez je peux ajouter l'explication des lignes dans le code ou tout au moins ce pourquoi vous avez des difficultés

Cord

Ce serai avec plaisir que d'avoir vos explications.

Bien cordialement

Ce serai avec plaisir que d'avoir vos explications.

Voilà qui est fait dans le post où je vous ai donné le code

Cordialement