Somme de plusieurs chiffre dans une seule cellule

Bonjour tout le monde,

J'ai une demande peut être un peu spéciale et qui va sûrement paraître bête. Je cherche à sommer des chiffres qui sont dans une seule cellule, écrite de cette manière:

"(3,1,0)"

Donc voilà, il y a du texte, les chiffres ne sont ni à gauche, ni à droite, ni au milieu donc pas possible d'utiliser les fonctions de position pour extraire ce qui m'intéresse. Mais je me dis qu'il y a peut être une formule qui saurait reconnaître les caractères numériques séparés au sein d'une même cellule. Ou alors un moyen d'aller chercher chaque nombre avec la position exacte ?

Pour ceux qui me diront de simplement répartir les trois nombres dans trois cellules différentes, je sais que c'est l'utilisation qu'excel attend de nous, mais j'ai vraiment besoin de les mettre dans une seule cellule.

Je vous remercie d'avance pour votre temps et vos réponses.

Bonsoir Corvus,

Bizarre comme demande mais tu dois avoir tes raisons :

=CNUM(STXT(A2;3;1))+CNUM(STXT(A2;5;1))+CNUM(STXT(A2;7;1))

Cette formule calculera la somme de ton exemple et de toutes les cellules qui ont exactement la même configuration à savoir "(3,1,0)"

Bonne continuation

Chris

Bonjour à tous ,

Si vous utilisez O365 alors pour les textes de la forme ( n1 , n2, n3, ... , toto , ni) vous pouvez utiliser la formule :

=SOMME(SIERREUR(1*FRACTIONNER.TEXTE(TEXTE.AVANT(TEXTE.APRES(A2;"(");")");",");0))

qui fait la somme des nombres entre les deux parenthèses en excluant tout ce qui n'est pas nombre.

...

Bonjour à tous,

Une autre méthode, on remplace VBA et on crée une fonction personnalisée :

= LAMBDA(x;
LET(
Ntxt;  SUBSTITUE(SUBSTITUE(x;"(";"");")";"");
Frac;  FRACTIONNER.TEXTE(Ntxt;;",")*1;
       SOMME(Frac)))

Dans onglet formule, on clique sur "Définir un nom" => On copie colle la formule comme ceci :

Une fois cela fait, on peut utiliser la nouvelle fonction créée.

=SOMME.TEXT(A1)

NB : Ceci ne fonctionne qu'avec O365.

Bonjour à tous !

Et.....

Dans la série "Les merveilleuses fonctions de M365", je propose, pour une valeur source en C2 :

=SOMME(REGEXEXTRACT(C2;"\d+";1)*1)

Bonjour à tous de nouveau !

Bien....

Je vous remercie de ce retour.

----> Pour une aide adaptée de la communauté, merci de préciser, dans votre profil, la nature de votre Excel ( 2019 ? 2021 ? 365 ? ...)
La langue est une information mineure.

Je vous remercie tous pour vos supers méthodes, très intéressant de voir tous les moyens plus ou moins directs d'accéder à ce que je voulais. J'apprends aussi la possibilité de créer des fonctions personnalisées dans Excel. Je pense avoir plus appris en 5min de lecture de vos réponses qu'en 3 ans de lycée et 2 d'univ.

La formule de JFL est typiquement ce que je m'étonnais de ne pas trouver dans Excel, ayant fait un peu de code je savais qu'il est facile pour une machine de repérer des nombres séparés par des virgules au sein d'un même bloc.

Merci tout le monde, rapide, simple et efficace cette communauté !