Ne faire apparaitre que la feuille Excel

Bonjour

Je suis a la recherche d'un code vba pour masquer tout ce qui ne sert plus a rien quand le fichier est terminé

exemple ruban,quadrillage,formule etc...

j'ai cherché sur la toile mais rien ne correspondait à ma demande.

Crdlt

Bonjour,

sur mes applications jeux qui sont en plein écran j'utilise ceci :

Sub Jouons()
    ' on arrête la mise à jour de l'écran
    Application.ScreenUpdating = False
    ' avec la fenêtre active (normalement celle de jeu sous Excel)
    With ActiveWindow
        ' les titres (A et 1)
        .DisplayHeadings = False
        ' scroll barre horizontale
        .DisplayHorizontalScrollBar = False
        ' scroll barre verticale
        .DisplayVerticalScrollBar = False
        ' les onglets
        .DisplayWorkbookTabs = False
        ' le quadrillage
        .DisplayGridlines = False
    End With
    ' avec l'application Excel
    With Application
        ' arrêt des calculs automatiques
        .Calculation = xlCalculationManual
        ' le ruban
        .ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",False)"
        ' la barre de formule
        .DisplayFormulaBar = False
        ' barre de status
        .DisplayStatusBar = False
        ' on met à jour l'écran
        .ScreenUpdating = True
    End With
End Sub

Ensuite, chemin inverse pour revenir à "la normale". On peut même avant de faire ceci mettre en mémoire les différents réglage afin de rendre l'application comme à l'origine.

C'est pourquoi je prévient qu'en cliquant sur le bouton, l'application va passer en plein écran...
un fichier :

@ bientôt

LouReeD

Bonjour LouReeD

Merci pour ton aide.

C'est tout bon j'ai trouvé la solution pour le problème évoqué ci-dessous

J'ai essayé d'adapter ton code à mon fichier ,ça ne fonctionne pas comme je le voudrais
Pourrais tu me le modifier afin que mes onglets ,les scrollbar vertical et horizontal restent visibles

Ma feuille se nomme ACCUEIL

J'avoue être perdu par moment avec le VBA

Crdlt

Re bonjour

Je reviens à la charge, j'ai bien résolu le problème pour la feuille qui a le bouton ,mais il faudrait que les codes

s'appliquent à plusieurs feuilles.

Bonsoir,

Windows, c'est la fenêtre "actuelle", donc je pense qu'il faut faire une boucle sur les feuilles et les instructions windows au milieu.

Application, c'est pour l'application Excel donc c'est valable pour tous les onglets.

A voir.

@ bientôt

LouReeD

Bonjour LouReeD

Je me doutais qu'il fallait faire une modif du code, mais là je plane à 20000.

Peux tu me faire une modif de ton code avec un exemple sur 2 ou 3 feuilles ?

Crdlt

Bonsoir,

en reprenant l'idée de mafraise pour le tableau des noms de feuille où vous voulez appliquer la mise en forme :

Sub Jouons()
    ' on arrête la mise à jour de l'écran
    Application.ScreenUpdating = False
    ' on boucle sur les feuille que l'on veut
    For Each nom In Array("Tableau1a16", "Tableau17a32")
        ' on active la feuille
        Sheets(nom).Activate
        ' avec la fenêtre active (normalement celle de jeu sous Excel)
        With ActiveWindow
            ' les titres (A et 1)
            .DisplayHeadings = False
            ' scroll barre horizontale
            .DisplayHorizontalScrollBar = False
            ' scroll barre verticale
            .DisplayVerticalScrollBar = False
            ' les onglets
            .DisplayWorkbookTabs = False
            ' le quadrillage
            .DisplayGridlines = False
        End With
    Next nom
    ' avec l'application Excel
    With Application
        ' arrêt des calculs automatiques
        .Calculation = xlCalculationManual
        ' le ruban
        .ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",False)"
        ' la barre de formule
        .DisplayFormulaBar = False
        ' barre de status
        .DisplayStatusBar = False
        ' on met à jour l'écran
        .ScreenUpdating = True
    End With
End Sub

A tester.

@ bientôt

LouReeD

Bonsoir

Merci pour l'exemple que tu m'as donné je l'ai mis en place et cela fonctionne bien.

Bonne soirée

Merci de votre retour ! Bonne fin de soirée !

@ bientôt

LouReeD