Formule Excel pour garder texte
Salut, j'ai du texte et la seule chose qui change c'est la date, j'aurais aimé faire en sorte de l'enlever pour ne garder que ceux qu'il y a au début et à la fin, est-ce que vous savez si c'est possible ?
Exemple :
Phrase avec la date qui peut changer : TEST POUR VOIR du 18/06/2024 - NOUS SOMMES LA SEMAINE
Résultat attendu : TEST POUR VOIR - NOUS SOMMES LA SEMAINE
Merci !
Bonjour,
Avec les fonctions gauche et droite
=GAUCHE(A1;14) & DROITE(A1;25)14 et 25 correspondent aux nombres de caractères a garder a gauche et a droite de la date (à retirer)
Merci !
Par contre j'ai oublié de préciser que le texte à gauche et à droite peut varier de longueur : )
Hello,
Teste ça pour un texte en H3 : je suis parti du principe qu'on aurait tout le temps le la chaîne " du XX/XX/XXXX" mais à un endroit différent
=SUBSTITUE(H3;STXT(H3;CHERCHE("/";H3;1)-6;CHERCHE("/";H3;1)+8-(CHERCHE("/";H3;1)-6));"")ou
=GAUCHE(H3;CHERCHE("/";H3;1)-6)&STXT(H3;CHERCHE("/";H3;1)+8;100)@+
bonjour
une contribution
avec texte en B3
=GAUCHE(B3;MIN(SI(ESTERREUR(STXT(B3;LIGNE($1:$200);1)*1);"";LIGNE($1:$200)))-4)&STXT(B3;MAX(SI(ESTERREUR(STXT(B3;LIGNE($1:$200);1)*1);"";LIGNE(1$:$200)))+2;50)cordialement
Bonsoir à tous !
Pour le "fun" et attiser la gourmandise de certains (
=REGEXREPLACE(A7;".{1,2} \d{1,2}.\d{1,2}.\d{2,4}";"")
Ça fonctionne merci beaucoup !
Bonjour à tous !
----> Ne pas oublier de passer le sujet en mode résolu !
Re salut,
J'ai une petite mordication à faire ^^
Dans le cas où il n'y a pas de "/" j'aimerais bien garder la valeur de la cellule.
Pour faire j'ai rajouté un "sierreur" mais je ne suis pas sur que ça soit propre même si ça fonctionne ^^
-> =SIERREUR(SUBSTITUE(I2;STXT(I2;CHERCHE("/";I2;1)-6;CHERCHE("/";I2;1)+8-(CHERCHE("/";I2;1)-6));"");I2)
Merci.
bonjour
c'est pour cela que j'avais privilégié a partir d'un chiffre
=GAUCHE(B3;MIN(SI(ESTERREUR(STXT(B3;LIGNE($1:$200);1)*1);"";LIGNE($1:$200)))-4)&STXT(B3;MAX(SI(ESTERREUR(STXT(B3;LIGNE($1:$200);1)*1);"";LIGNE($1:$200)))+2;50)cordialement