[Power Query] Filtre à l'intérieur d'une Table

Bonjour,

Dans cet exemple très simplifié, j'obtiens une colonne supplémentaire par un GroupBy, qui me donne donc une Table par ligne.

Est-il possible (sans Expand préalable) d'effectuer un filtre à l'intérieur de chaque Table, et par exemple, ne conserver que les lignes dont la couleur est égale à "Blanc"

Je précise que ce filtre ne doit pas s'effectuer avant le GroupBy, mais qu'il faut bien "Filtrer" à l'intérieur de chaque Table après le GroupBy

Merci par avance

Bonsoir à tous !

Comme ceci ?

let
    Source = Excel.CurrentWorkbook(){[Name="T_Data"]}[Content],
    #"Lignes groupées" = Table.Group(Source, {"Jour", "Mois"}, {{"Tbl", each Table.SelectRows(_,each [Couleur]="Blanc")}})
in
    #"Lignes groupées"

Hi,

Merci pour ce premier jet...

Mais (et oui, il y a un Mais)

Je souhaite conserver l'étape "GroupBy" en l'état....

Et ne faire le SelectRows qu'après (nouvelle étape)

Merci

Bonsoir,

Je ne vois pas trop pourquoi après et pas simultanément, mais :

Pour filtrer la colonne de tables sans ajout de colonne

= Table.TransformColumns( #"Lignes groupées", {"Tbl", each Table.SelectRows(_, each [Couleur]="Blanc")})

Par ajout d'une nouvelle colonne

= Table.AddColumn(#"Lignes groupées", "Tbl_Filtrée", each Table.SelectRows([Tbl], each [Couleur]="Blanc"))

A+

Bonjour,

Et merci pour les réponses...

J'ai donné, je pense, une version trop simplifiée de mon besoin.

Dans le fichier joint, j'ai simulé la situation dans laquelle je me trouve, suite à une fusion.

Dans la colonne "Tbl", une liste de "Table"

Dans la colonne "Choix", la couleur voulue. (Ici, il n'y en a qu'une, mais dans la vraie vie, il y en aurait bien plus)

J'aimerais donc que le filtre se fasse dans chaque "Table" sans Expand préalable (mes fichiers comportent plusieurs milliers de lignes, et même si PQ est capable de les traiter, je préfère "sans")

Merci pour toute aide supplémentaire (et désolé pour le "feuilletonnage" si cher à JFL...)

Bonjour à tous !

Une proposition ?

let
    Source = Excel.CurrentWorkbook(){[Name="T_Data"]}[Content],
    GroupBy = Table.Group(Source, {"Jour", "Mois"}, {{"Tbl", each _, type table [Jour=text, Mois=text, Couleur=text]}}),
    AjtChoix = Table.AddColumn(GroupBy, "Choix", each "Blanc"),
    TblFiltrée = Table.AddColumn(AjtChoix, "TblFiltrée", (x)=> Table.SelectRows(x[Tbl], each [Couleur]=x[Choix]))
in
    TblFiltrée

Re-,

Parfait

Merci encore, et bon dimanche

Bonjour à tous de nouveau !

C'est déjà terminé ? Je suis presque frustré...

Je vous remercie de ce retour.

Et..... bon dimanche à vous aussi !

Re-,

JFL a écrit :

C'est déjà terminé ? Je suis presque frustré...

Petite saison pour cette série, désolé

Merci encore