Formules prenant en compte les retours à la ligne

Bonjour à tous,

Je vous écris car j'ai un petit problème qui sera sûrement très simple à régler pour vous mais moi j'y arrive pas :(

J'ai un tableau avec dans la 1ere colonne le nom et prénom des personnes et dans la 2e colonne leur adresse mail. A côté j'ai une macro qui me permet de faire une liste déroulante à choix multiples (je peux sélectionner plusieurs noms dans la liste déroulante qui me les affiche les uns en dessous des autres en revenant à la ligne).

J'aimerai une formule qui va chercher le nom des personnes dans la liste et qui m'affiche leur mail. La difficulté est que comme les noms sont séparés d'un retour à la ligne, les formules que je connais n'arrivent pas aller chercher le nom des personnes (Il peut y en avoir une dizaine dans une case).

Auriez-vous une idée ?

Je vous mets un fichier Excel pour illustrer tout ça.

Merci d'avance.

7test.xlsx (9.90 Ko)

Bonjour

en C3 à étirer en dessous

=JOINDRE.TEXTE(";";;FILTRE($C$14:$C$20;ESTNUM(EQUIV("*"&$B$14:$B$20&"*";B3;0));""))

En revanche je en sais pas les mettre dans l'ordre de B3 : c'est celui de B14;B20 qui est pris

Bonjour à tous,

Une autre !

=JOINDRE.TEXTE(";";;RECHERCHEX(FRACTIONNER.TEXTE(B6;CAR(10));$B$14:$B$20;$C$14:$C$20;""))

Crdlmt

Bonjour à tous !

Une proposition formule unique et dynamique (en C3) ?

=MAP(
    B3:B6;
    LAMBDA(x;
        JOINDRE.TEXTE(
            "; ";
            ;
            RECHERCHEX(FRACTIONNER.TEXTE(x; ; CAR(10)); B14:B20; C14:C20; "--"; 0)
        )
    )
)

Bonjour à tous,

Merci pour vos réponses ! J'y ai trouvé mon bonheur !

Bonjour à tous !

Excellente chose !

Je vous remercie de ce retour.

Rechercher des sujets similaires à "formules prenant compte retours ligne"