Trouver la valeur de la dernière sur une plage filtré sur Excel

Bonjour,

Je n'arrive pas à trouver la solution à mon problème. Je veux trouver la valeur de la dernière cellule sur une plage filtré.

Avec cette formule j'ai la valeur de la dernière valeur de tout mon tableau.

=RECHERCHE(2;1/(B11:B500<>"");B11:B500)

Moi je souhaite la dernière valeur sur la plage filtré.

D'avance merci pour votre aide

Claude

Bonsoir,

que ce soit filtré ou pas, ça devrait renvoyer la valeur de la dernière cellule non vide.

Quel est le souci, la formule ne trouve rien ? Comment la plage est-elle filtrée ?

Bonjour,

Je trouve ma valeur mais pas la dernière quand j'applique le filtre. Ma dernière valeur non filtrer c'est MAR et si je filtre je devrais avoir comme résultat MTX

Bonsoir à tous !

Il serait judicieux de joindre un classeur représentatif à l'appui de votre demande......

J'ai fait un petit fichier exemple mon dernier chiffre est le 59.

Si je sélectionne un chiffre (exemple 10) , je souhaiterais retrouvé ma valeur 10 dans la case C3.

Est la j'ai toujours ma valeur 59

Bonsoir à tous de nouveau !

Votre demande est peu explicite.

Vous évoquiez un filtre mais vous n'en précisez pas les conditions.

Pour la plage A3:A200 de votre classeur exemple, si vous désirez retourner la dernière valeur filtrée :

- Condition : valeur non nulle :

=PRENDRE(FILTRE(A3:A200;A3:A200<>"");-1)

- Conditions : Valeur non nulle et < 20 :

=PRENDRE(FILTRE(A3:A200;(A3:A200<>"")*(A3:A200<20));-1)

Re bonjour,

j'ai testé votre ligne et cela ne fonctionne pas. J'ai mis l'exemple le test que j'ai fait.

Merci de votre réponse

Bonjour Claude Mettraux , bonjour à tous,

Dans la cellule D2 , une formule matricielle qui devrait fonctionner avec toutes les versions d'Excel et pour un filtre quelconque :

=INDEX(A:A;LIGNE(A2)+GRANDE.VALEUR(SI(SOUS.TOTAL(103;DECALER(A2;LIGNE(1:9999);0));LIGNE(1:9999));1))

• Au téléchargement du classeur joint, le filtre du classeur est le filtre textuel "ne se termine pas par e". On peut bien entendu modifier le filtre voire le supprimer
• Augmenter la valeur 9999 si le tableau non filtré dépasse la ligne 9999 (cette valeur peut aussi être diminuée - par exemple si le tableau ne dépasse jamais la ligne 500, on pourrait remplacer 9999 par 999)

Bonjour,

Alors j'ai fait le test avec la formule de "mafraise" et cela fonctionne exactement comme je le voulais.

Encore un grand merci pour votre aide.

Bonjour à tous !

Avec votre dernier classeur exemple, je perçois enfin votre vision du "filtre".

Je vous propose de tester la formule suivante :

=LET(p;A3:A200;PRENDRE(FILTRE(p;(p<>"")*(MAP(p;LAMBDA(x;SOUS.TOTAL(103;x)))));-1))

La plage "p" est à adapter à votre environnement.