Sélectionner les deux premières cellules non vides en colonne "A" et "B"

Bonjour à tous,

Comment puis-je trouver la première ligne dont les deux cellules (En colonnes "A" et "B") qui ne soient pas vide.

Dans mon cas en pièce jointe, la première ligne dont les cellules en colonne "A" et "B" sont non vides est la ligne numéro 11.

Prévoir SVP une solution en vba, j’ai essayé de mon coté

de mettre en application un code avec des tableaux sans aucune réussite, je vous le soumet afin que vous puissiez m’aider à le finaliser.

Je reste à votre disposition et d’avance merci pour vos propositions.

Bonjour Harzer ,

Essayez le code suivant (cliquer sur le bouton Hop!) :

Sub Test()
Dim xrgA As Range, xrgB As Range, xrgIntersect As Range
   With Sheets("Pedigree")
      Application.Goto .Range("a1"), True
      On Error Resume Next
      Set xrgA = .Columns(1).SpecialCells(xlCellTypeConstants)
      Set xrgB = .Columns(2).SpecialCells(xlCellTypeConstants)
      Set xrgIntersect = Intersect(xrgA, xrgB.Offset(, -1))
      On Error GoTo 0
      If xrgA Is Nothing Or xrgB Is Nothing Or xrgIntersect Is Nothing Then Exit Sub
      xrgIntersect(1).Resize(, 2).Select
   End With
End Sub

...

Re,

Si vous désirez une méthode par tableau, essayez :

Sub Test()
Dim derlig As Long, t, i As Long
   With Sheets("Pedigree")
      Application.Goto .Range("a1"), True
      derlig = .UsedRange.Row + .UsedRange.Rows.Count
      t = .Range("a1:b" & derlig)
      For i = 2 To UBound(t)
         If t(i, 1) <> "" And t(i, 2) <> "" Then Exit For
      Next i
      If i <= UBound(t) Then .Cells(i, "a").Resize(, 2).Select
   End With
End Sub

...

Bonjour mafraise,

Merci pour les deux propositions, elles fonctionnent très bien toutes les deux.

Toutefois, la solution avec les tableaux est exceptionnellement très rapide. Grand MERCI à vous.

Cordiale poignée de mains.

Bonsoir,

je donne à tout hasard une solution par MFC : mettre dans une cellule cette formule matricielle (par exemple en Q1) ;

=EQUIV(VRAI;SI(SI(ESTVIDE(A2:A20);LIGNE(A2:A20))=SI(ESTVIDE(B2:B20);LIGNE(B2:B20));VRAI);0)+1

Renvoie 11. Le +1 à la fin c'est parce que la plage commence à la 2ème ligne et pas la 1ère.

Et comme formule de MFC appliquée à $A$2:$B$20 ;

=LIGNE(A2)=$Q$1

Bonjour Doux Rêveur,

Merci pour votre proposition, elle fonctionne bien.

Cordiale poignée de mains.