Truc bête mais prise de tête

Bonjour à tous,

SVP un petit coup de main pour m'aider à comprendre ce qui ne marche pas dans cette petite routine tant simple mais qui refuse de fonctionner.

Sub check_it()
'
'
'
Dim jour As Range
Dim datejour
Dim cpt As Long
Dim maplage As Range
Dim ws As Worksheet

Set ws = ThisWorkbook.Sheets("ORDRES")
cpt = ws.Range("M2").End(xlDown).Row 'On compte le nombre d'enregistrements dans la feuille

datejour = Format(Day(Now), "00") ' On récupère la date du jour au format 00
MsgBox ("contrôle pour la journée du " & datejour) ' On contrôle si des opération ont lieu à J

Set maplage = ws.Range("M2:M" & cpt) ' plage de recherche

For Each cell In maplage
If cell.Value = datejour Then 'si la valeur de M&cpt est égale à la date du jour
' **** Sauf qu'il ne trouve pas d'équivalence entre les 2 valeurs

ActiveCell.Select
ActiveCell.EntireRow.Font.ColorIndex = 3
End If

Next cell

End Sub

****** Merci d'avance, Bonne soirée **********

Bonjour,

Qu'est ce qu'il y a dans la colonne M ?
datejour = Format(Day(Now), "00") A mon avis ça... Vu avec ma boule de cristal : Ça n'a pas de sens !

Et ça c'est le pompon :

ActiveCell.Select

Si c'est l' ActiveCell bien sur qu'elle est sélectionnée !

Bon. A mon avis t'es mûr pour nous mettre ton bout de fichier.

A+

Salut, dans la colonne M il y a le Jour qui correspond à l'échéance mensuelle "Chaque 5 du mois" = 5

Bonjour,
Une proposition.
Cdlt.

Sub check_it()
Dim ws As Worksheet
Dim maplage As Range, cell As Range
Dim cpt As Long, jour As Integer

    Set ws = ThisWorkbook.Worksheets("ORDRES")

    jour = Day(Date)
    MsgBox ("contrôle pour la journée du " & jour)

    With ws
        cpt = .Range("M2").End(xlDown).Row
        Set maplage = .Range("M2:M" & cpt)
        For Each cell In maplage
            If cell.Value = jour Then
                .Cells(cell.Row, 1).Resize(, 13).Font.ColorIndex = 3
            End If
        Next cell
    End With

End Sub

Merci Jean Eric ça fonctionne nickel ... je vais maintenant regarder d'où venait mon problème . En tous cas super sympa