Problème de couleur sur la mise en forme conditionelle
Bonjour,
Je me trouve dans le cadre d'un inventaire informatique et en ce moment je m'occupe de la réserve.
J'ai instauré 3 couleur le vert pour dire qu'il y a assez de en réserve, le jaune pour dire qu'il y en a juste assez et le rouge s'il manque de la réserve.
Donc dans les mise en forme conditionnelle sur chacune des cellules je met les 3 conditions (Plus , autant ou moins que la quantité demandé).
jusque la sa marche.
Ensuite j'ai voulu rajouter dans ma cellules mise en couleur le nombre qu'il faudrait pour être dans le jaune (juste assez). Voici la formule utilisé.
="29/"&NB.SI.ENS(C6:C88;"<>";C6:C88;"<>*Salle*";C6:C88;"<>*Portable*")
Et finalement la couleur obtenue n'est pas la bonne, car j'obtiens une couleur verte alors que mon résultat est inférieur donc devrait apparaitre en rouge.
J'ajoute un fichier Excel si besoin.
Merci de votre temps.
Bonjour,
deux choses :
La première est que les MFC sous Excel 2010 et + ont été simplifiées :
vous sélectionnez la première cellule de la plage où vous voulez appliquer la MFC, puis une fois que ceci fonctionne, il suffit de modifier la plage "s'applique à" pour adapter la MFC sur la plage voulue.
La Deuxième : lors de l'entrées des formules vous ne deviez pas avoir sélectionner la cellule concernée par la MFC et Excel à adapter à sa sauce la formule, regardez à quoi elle correspond maintenant : B19<NB.SI.ENS(XFD9:XFD1048503;"<>";XFD9:XFD1048503;"<>*Salle*";XFD9:XFD1048503;"<>*Portable*")
Je ne pense pas que vous ayez des données en colonne XFD !
@ bientôt
LouReeD
Bonjour, Merci beaucoup de votre réponse.
Tout d'abord merci des conseil sur le fait d'étendre mes MFC et pas de les dupliquer car sa devenais illisible.
Et effectivement je n'avais aucun colonne XFD ! Donc j'ai pu le remettre sur la bonne colonne, mais malheureusement tout vos conseil qui on permis d'amélioré mes MFC n'ont pas résolu encore le problème des couleur.
Merci de votre aide et de votre temps :)
Je remet le fichier excel mis a jour par vos conseil.
Bonjour Theglitch, LouReed, le forum,
En modifiant légèrement votre formule en B19 (le chiffre n'est plus dans les guillemets) et suivantes et la MFC correspondante, cela fonctionne.
Regardez le classeur :
Cordialement.
AL 22
Bonjour AL 22, Merci de votre réponse.
Alors Ce que vous m'avez envoyez marche a merveille mais sur mon exemple et je ne vois pas pourquoi cela ne fonctionne pas dans mon fichier.
Pour être sure les lignes que vous avez changer sont :
=6&"/"&NB.SI.ENS(C4:C14;"<>";C4:C14;"<>*Salle*";C4:C14;"<>*Portable*")
=--GAUCHE(B19;1)<NB.SI.ENS($C$4:$C$14;"<>";$C$4:$C$14;"<>*Salle*";$C$4:$C$14;"<>*Portable*")
Je ne vois que ça, sauf si je me trompe bien sure. Donc j'ai remplacer dans mon fichier et ça donne cela (juste des changement de ligne et de colonne).
=32&"/"&NB.SI.ENS(C6:C88;"<>";C6:C88;"<>*Salle*";C6:C88;"<>*Portable*")
=--GAUCHE(E99;1)<NB.SI.ENS($C$6:$C$88;"<>";$C$6:$C$88;"<>*Salle*";$C$6:$C$88;"<>*Portable*")
le formule est appliqué donc en E99 et j'arrive avec résultat un 32/31 rouge :(
Ai-je fait une erreur ?
Merci de votre réponse et de votre temps !
Re,
Effectivement, je n'ai modifié que ces deux éléments.
Il est normal que cela ne fonctionne pas car dans la MFC, la fonction GAUCHE s'applique à un seul caractère. (le deuxième argument de la fonction concerne le nombre de caractères)
Il faut donc modifier par :
--GAUCHE(E99;2)Les 2 caractères (32) seront pris en compte.
AL 22
Bonjour,
en reprenant la partie gauche des formules de AL 22, je vous propose ce fichier qui contient que trois conditions qui se reportent sur la plage des 4 cellules.
En effet, au début vous aviez 3 couleurs par cellule vu que ces cellules ne comportaient pas les mêmes formules de recherche de données.
Mais je me suis aperçue que ces formules "remplissent" les cellules, donc pas besoin de les recalculer dans la MFC, on travaille directement sur le résultat comme avec la partie gauche de la formule, on obtient alors trois formules :
Vert =--Gauche(B19;1)>--DROITE(B19;1)
Jaune =--Gauche(B19;1)=--DROITE(B19;1)
Rouge =--Gauche(B19;1)<--DROITE(B19;1)
et ces formules s'appliquent sur la plage B19:B22
Le fichier :
@ bientôt
LouReeD
Re,
Bravo LouReed !
AL 22
Et pour simplifier en s'adaptant au différentes tailles des tests : 3/5; 9/12; 32/14; 85/123, vous pouvez utilisez ces formules :
vert : =--GAUCHE(B19;TROUVE("/";B19)-1)>--DROITE(B19;NBCAR(B19)-TROUVE("/";B19))
jaune :=--GAUCHE(B19;TROUVE("/";B19)-1)=--DROITE(B19;NBCAR(B19)-TROUVE("/";B19))
rouge :=--GAUCHE(B19;TROUVE("/";B19)-1)<--DROITE(B19;NBCAR(B19)-TROUVE("/";B19))
En fait, on recherche le Slash et ceci nous permet d'extraire le nombre de caractère avant et après pour faire la comparaison.
Donc trois MFC sur une plage de cellule...
@ bientôt
LouReeD
Re,
Merci a vous deux de vos réponses et du temps que vous y avez consacrer.
Je n'ai enfin plus de problème avec ces couleurs, merci des astuces et des réponses que vous m'avez apporté :)
Merci LouReeD et AL 22.
Bonne journée !