Nom [résolu] export feuilles selectionnées

Bonjour,

Je suis parvenu à rédiger un code qui fonctionne et qui me permet de sélectionner des feuilles de mon classeur et de les exporter de façon individuelle. Cependant, le nom de chaque fichier exporté est identique. Or, je souhaite que le nom de chaque fichier soit le nom de la feuille selectionné. Je n'arrive pas à trouver la bonne méthode pour le filename ("??" ci-dessous).

Private Sub Exporter_Click()
Dim I As Integer
  Me.Hide
    With Application.FileDialog(msoFileDialogFolderPicker)
        If .Show = -1 Then
            chemin = .SelectedItems(1) & "\"
        End If
         End With

  With ListBox1
    For I = 0 To .ListCount - 1
        If .Selected(I) Then
          Sheets(.List(I)).ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
                                    chemin & "??", Quality:= _
                                     xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
                                     OpenAfterPublish:=True
        End If
    Next I
  End With
End Sub

Je n'ai pas trouvé la solution sur les forums jusqu'ici.

Merci pour votre aide.

Maxime

Bonjour Monroe, a tester

Private Sub Exporter_Click()
    Dim I As Integer
    Me.Hide
    With Application.FileDialog(msoFileDialogFolderPicker)
        If .Show = -1 Then
            chemin = .SelectedItems(1) & "\"
        End If
    End With

    With ListBox1
        For I = 0 To .ListCount - 1
            If .Selected(I) Then
                Dim NomFeuille As String
                NomFeuille = Sheets(.List(I)).Name ' Obtenez le nom de la feuille
                ' Utilisez le nom de la feuille comme nom de fichier
                Sheets(.List(I)).ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
                    chemin & NomFeuille & ".pdf", Quality:= _
                    xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
                    OpenAfterPublish:=True
            End If
        Next I
    End With
End Sub

Merci pour votre aide @stepaustras, cela marche parfaitement !! :D

ok