Envoi email a date écheance

Bonjour,

J'ai un fichier excel ou se trouve une colonne avec diverses dates et je souhaiterais recevoir par email une alerte si une de ces dates de cette colonne arrive à la date du jour via outlook.

Merci par avance.

Cdt.

Bonsoir Danymaccoy,

Peut-être avec un code de ce style, à mettre dans un module

Option Explicit

Const olMailItem As Integer = 0

Sub Envoyer_Mail_DateEchu()
  Dim ObjOutlook As Object, ObjMail As Object
  Dim ShtS As Worksheet ' Pour définri la feuille source
  Dim dLig As Long, Lig As Long
  ' Définir la feuille à traiter, ICI -> Données
  Set ShtS = ThisWorkbook.Sheets("Données")
  ' Dernière ligne remplie de la colonne A
  dLig = ShtS.Range("A" & Rows.Count).End(xlUp).Row
  ' Définir une instance d'Outlook
  Set ObjOutlook = CreateObject("Outlook.Application")
  ' Avec chaque ligne
  For Lig = 2 To dLig
    ' Disons que c'est la colonne D qui contient la date
    If ShtS.Range("D" & Lig) >= Date Then
      Set ObjMail = ObjOutlook.CreateItem(olMailItem)
      With ObjMail
        .Display  ' Pour afficher al signature
        .To = "xxxx@gmail.com" ' le destinataire
        .Subject = "Rappel date d'échéance" ' l'objet du mail
        .HTMLbody = "Bonjour, <br>" _
        & "La date d'échéance du " & ShtS.Range("D" & Lig) & " est arrivée à terme.<br>" _
        & "Merci de faire le nécessaire SVP" & .HTMLbody
        .Send  ' Pour l'envoyer directement
      End With
      Set ObjMail = Nothing
    End If
  Next Lig
  Set ObjOutlook = Nothing
End Sub

En l'appelant de ThisWorkbook avec

Private Sub Workbook_Open()
  Call Envoyer_Mail_DateEchu
End Sub

A+

Bonsoir,

Je vais essayer et merci encore.

Bonne soirée

Cdt