Comment trouver la date la plus récente par 'catégorie avec power query ?

BOnjour

j'ai une liste de cleint avec differentes dates et montants

je voudrais via power query, ne voir qu'une seule ligne par client reprenant la date la plus récente avec le montant correspondant

j'ai essayé un formule mais ca me ressort la date la plus recente de tout le fichier e

t non la plus récente par client

vous trouverez ci joint le fichier . pouvez vous m aider ? merci par avance

Hello,

Une proposition, tu peux rajouter des lignes dans ton tableau et des nouveaux clients, normalement les formules vont suivre sans problème.

@+

pouvez vous juste me donner le langage M svp , merci par avance :)

Hello,

Essaie ça

let
    Source = Excel.CurrentWorkbook(){[Name="Tableau1_2"]}[Content],
    #"Type modifié" = Table.TransformColumnTypes(Source,{{"Client", type text}, {"Dates", type date}, {"Montant", Int64.Type}, {"Dates revues", type datetime}}),
    #"Lignes triées" = Table.Sort(#"Type modifié",{{"Client", Order.Ascending}, {"Dates", Order.Descending}}),
    #"Lignes groupées" = Table.Group(#"Lignes triées", {"Client"}, {{"Date Max", each Record.Field(Table.First(_),"Dates")},{"Montant", each Record.Field(Table.First(_),"Montant")}})
in
    #"Lignes groupées"

@+

Bonjour,

ou ça :

= Table.Group(#"Type modifié", {"Client"}, {{"Date_Max", each List.Max([Dates]), type nullable date}})

A+

Oups, oublie, je n'avais pas vu que tu voulais aussi les montants.

merci bcp :)

Hello,

C'est ce qui était recherché ?

Si oui n'hésite pas à passer le sujet en résolu et si tu as des questions n'hésite pas également

@+

oui c'était la silution attendue

j'ai une autre question

je voudrais que power query me garde la date la plus récente et la plus lointaine avec les montants correspondant, et ce pour chaque client. Avec la solution proposée, je ne vois pas trop comment cela peut fonctionner.

Des idées pour le langage M ? merci bcp :)

Bonjour à tous !

Une approche ?

let
    Source = Excel.CurrentWorkbook(){[Name="Tableau1"]}[Content],
    TypeDate = Table.TransformColumnTypes(Source,{{"Dates", type date}}),
    GroupBy = Table.Group(
                            TypeDate,
                            {"Client"},
                            {
                                {"Date récente", each List.Max([Dates]), type date},
                                {"Mt récent", each Table.Sort( _,{"Dates",1})[Montant]{0}, Currency.Type},
                                {"Date ancienne", each List.Min([Dates]), type date},
                                {"Mt ancien", each Table.Sort( _,{"Dates",0})[Montant]{0}, Currency.Type}
                            }
                         )
in
    GroupBy

merci bcp :)

Bonjour à tous de nouveau !

Je vous remercie de ce retour.