Calcul moyenne valeurs extraites sur plusieurs cellules
Bonjour,
La chose me semblait simple au premier abord, mais finalement je galère...
J'ai une colonne contenant des données du type :
duration=3904
duration=3881
duration=8311
duration=8311
duration=4385
duration=4385
duration=748
duration=748
duration=37572
duration=37572
duration=840
duration=839
duration=12612
Ce sont des durées en secondes pour lesquels j'aimerais calculer la moyenne (à noter que certains cellules sont vides).
J'ai donc d'abord tenter de procéder à l'isolement de la partie numérique avec des formules du type
=(CNUM(STXT(A:A;10;99)))
ou bien =CNUM((DROITE(A:A;NBCAR(A:A)-TROUVE("=";A:A))))
mais dès lors que j'y ajoute la MOYENNE, ça ne me renvoie que la valeur de la cellule elle-même...
J'apprécierais donc beaucoup votre aide
Merci pour votre réponse rapide et qui semblait fonctionner, mais je me rends compte que, bien qu'il y ait une valeur moyenne inscrite à l'ouverture (probablement en cache lors de votre sauvegarde), dès que je me mets dans la barre d'édition, et sans rien y modifier, et que je réactive la formule matricielle (avec ctrl+shift+enter), je me retrouve avec une erreur #NOM?.
Bonsoir,
Ou avez vu que la solution de djidji59430 que je salue, avait besoin de CTRL+SHIFT+ENTER
Elle utilise des fonctions natives d'Excel 2019 et postérieur
A+
Je viens de retélécharger le fichier déposé par DjiDji59430
Quand je l'ouvre, j'ai bien les accolades... Est-ce que c'est mon Excel qui a un pb ?
Et que je valide la cellule (sans la modifier) avec "enter" ou "ctrl+shift+enter", j'obtiens toujours l'erreur #NOM? ...
Re,
Vous ne devez pas avoir mise à jour de votre version
Car il est pourtant indiqué sur le site de Microsoft "Excel 2019"
Sinon, il reste une colonne à mettre en plus
ou une requête PQ
A+
Bonjour à tous !
Contrairement aux informations données par l'aide Microsoft, il me semble que la fonction FILTRE n'est pas intégrée dans Excel 2019.
Re
le coup du filtre pour 2019, je l'avais deja vu, en plus !
avec une formule :
=SOMME(SIERREUR(CNUM(STXT($G$4:$G$18;10;99));0))/NB(CNUM(STXT($G$4:$G$18;10;99)))
Crdlmt
Bonjour à tous de nouveau !
Autre approche :
=MOYENNE(SIERREUR(CNUM(STXT($G$4:$G$18;10;99));""))(Accompagnée, si besoin est, d'une validation matricielle)
mon approche avec l'utilisation de "Duration=" et je ne pense pas qu'elle est matricielle
=MOYENNE(AGREGAT(14;6;STXT($G$4:$G$18;10;10)/(GAUCHE($G$4:$G$18;9)="duration=");SEQUENCE(NB.SI($G$4:$G$18;"duration=*"))))
EDIT : la version ici dessus est pour >= 2021-365, pour 2019 je pense ceci
=MOYENNE(AGREGAT(14;6;STXT($G$4:$G$18;10;10)/(GAUCHE($G$4:$G$18;9)="duration=");LIGNE(DECALER($A$1;;;NB.SI($G$4:$G$18;"duration=*");))))bonsoir
ou alors qui donne 9546.7...
=SOMME(SIERREUR(SUBSTITUE(G4:G18;"duration=";"")*1;0))/NBVAL(G4:G18)Merci à tous !
Finalement c'est la solution de JFL
=MOYENNE(SIERREUR(CNUM(STXT($G$4:$G$18;10;99));""))
avec une validation matricielle qui a fonctionné, et qui me semble être la plus "simple".
Bonsoir à tous de nouveau !
Et...merci de ce retour.