Macro pour vérifier si une série de dates correspond à un jour férié listé

Bonjour,

j'ai mis en lien le fichier que je suis en train de créer.

Je voudrai via une macro réduire à une valeur définie fixe la largeur de la colonne qui contient un jour férié. ( les jours fériés sont listés en "données") en lisant chaque date du mois. ( le mois affiché étant variable)

Je tourne en rond à tenter d'écrire une macro...

nota j'ai laissé les deux macros que j'ai réussi à faire fonctionner.

merci pour votre aide.

Hello,

Une proposition :

Sub ColumnWidth()
    Const strNameWksCalendar As String = "Feuil1"
    Const strNameWksFeries As String = "données"

    Dim bytDayRow As Byte, bytLastColDay As Byte, bytCol As Byte, bytFirstCol As Byte
    Dim rngFeries As Range
    Dim booFerie As Boolean

    Set rngFeries = Worksheets(strNameWksFeries).[g6:g18] ' Plage de cellules des jours fériés
    With Worksheets(strNameWksCalendar)
        bytDayRow = 11 'Ligne des jours
        bytFirstCol = 5 ' Premiere colonne de date
        bytLastColDay = .Cells(bytDayRow, .Columns.Count).End(xlToLeft).Column 'Dernier jour
        For bytCol = bytFirstCol To bytLastColDay Step 2
            booFerie = IsError(Application.VLookup(CLng(.Cells(bytDayRow, bytCol)), rngFeries, 1, False))
            If booFerie = False Then Union(.Columns(bytCol), .Columns(bytCol + 1)).ColumnWidth = 1
        Next bytCol
    End With
    Set rngFeries = Nothing

End Sub

Merci Rag02700

test concluant, je vais maintenant tenter de comprendre la construction.

Hello,

1 je definis la plage des jours fériés de la feuille données g6:g18

2 je definis la ligne des jours de la feuille du calendrier (ligne 11 dans ton exemple) + la colonne du premier jour à tester soit la colonne E donc 5eme col

3 je fais une boucle sur la ligne 11, de la premiere colonne de date (donc 5) à la derniere colonne avec un pas de 2 (step 2) ex : col 5;col7;col9 ....

4 je fais une recherchev dans la plage des jours fériés de la date

5 si la recherchev retourne une erreur, cela veut dire que la date cherchée n'est pas dans la plage des jours fériés.

6 si false donc trouvé, je réduis la taille de la colonne du matin + après midi