Macro enregistrement en PDF

Bonjour à tous,

Petit souci pour moi, mais certainement solutionné en 5 sec pour vous :

J'ai cette macro :

VB:

Sub animateur()

Dim w As Worksheet

Application.ScreenUpdating = False

Application.DisplayAlerts = False

Sheets(Array("Entrées du soir", "Box Office")).Copy

With ActiveWorkbook

For Each w In .Worksheets

w.UsedRange = w.UsedRange.Value

Next

.SaveAs ThisWorkbook.Path & "\Résultats du jour.xlsm", 52

.Close

End With

End Sub

Mais j'aimerai que l'enregistrement se fasse PDF, cela est-il possible ?

Si oui pouvez vous m'indiquer le code modifié, svp ?

Alors j'ai essayé en mettant juste .pdf à la place de .xlsm mais le lecteur de pdf ne fonctionne pas, pourtant le fichier s'enregistre.

Bonjour,

1123 sujets en parlent...

Tu y trouveras sûrement ton bonheur.

Bon courage

Bonjour le fil, bonjour le forum,

Peut-être comme ça :

Sub ThauTheme()
Dim w As Worksheet
Dim CA As String

CA = ThisWorkbook.Path & "\"
Application.ScreenUpdating = False
Application.DisplayAlerts = False
With ActiveWorkbook
    For Each w In .Worksheets
        If w.Name = "Entrées du soir" Or w.Name = "Box Office" Then
            w.Copy
            ActiveWorkbook.Worksheets(1).ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
            CA & w.Name & ".pdf", Quality:=xlQualityStandard, IncludeDocProperties _
            :=False, IgnorePrintAreas:=False, OpenAfterPublish:=False
            ActiveWorkbook.Close False
        End If
    Next
End With
End Sub

Re,

Alors en effet cela fonctionne et je t'en remercie vivement par contre il me génère deux pdf distinct.

Dans la version xlsm, j'avais les deux ensemble avec comme nom de fichier "Resultats du jour".

Crois tu qu'il est possible de regrouper ?

Re,

Figure toi que j'avais plusieurs fois essayé en vain d'enregistrer plusieurs onglets dans un PDF. Grâce à ton code j'ai enfin réussi.

Sub ThauTheme()
Dim w As Worksheet
Dim CA As String

CA = ThisWorkbook.Path & "\"
Application.ScreenUpdating = False
Application.DisplayAlerts = False
Sheets(Array("Entrées du soir", "Box Office")).Copy
ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
  CA & "Résultats du jour" & ".pdf", Quality:=xlQualityStandard, IncludeDocProperties _
  :=False, IgnorePrintAreas:=False, OpenAfterPublish:=False
ActiveWorkbook.Close False
End Sub

Merci de ton retour et si en plus j'ai pu t'aider magnifique.

Bonne journée