Transfert de données entre tableaux (archivage)

Bonjour le forum,

J'essaye de créer une macro pour archiver les données d'un Tableau 1 dans un Tableau 2 en ajoutant une date dans la colonne 1 du Tableau 2 et en calculant un total de données. plus facile de comprendre avec le fichier ci-joint
est-ce des idées? ou des pistes ?

Bonjour

il n'y a pas d'heure dans ton tableau

A+ François

Bonjour François,

Merci pour ton intérêt. Je ne cherche pas le total des heures c pour cette raison que je n'ai pas ajouté ni la formation ni son code

je cherche à calculer le nombre de fois chaque employé a suivi une formation par date car le Tableau 1 est mis à jour chaque semaine et je veux archiver les données de chaque semaine

Merci

Bonjour,
Une proposition à étudier.
Cdlt.

Public Sub ArchiveData()
Dim t_input As ListObject, t_output As ListObject
Dim pt As PivotTable
Dim r As Range, rngData As Range
Dim dt As Double, n As Double

    Application.ScreenUpdating = False
    Set t_input = Range("t_données").ListObject
    dt = Range("_date").Value2
    If Not t_input Is Nothing And dt > 0 Then
        Set t_output = Range("t_synthèse").ListObject
        Set pt = Worksheets("TCD").PivotTables(1)
        pt.RefreshTable
        n = pt.DataBodyRange.Rows.Count
        With t_output
            If .InsertRowRange Is Nothing Then
                Set r = .HeaderRowRange.Cells(2).Offset(.ListRows.Count + 1)
            Else
                Set r = .InsertRowRange.Cells(2)
            End If
        End With
        With r
            .Resize(n, 3).Value = pt.TableRange1.CurrentRegion.Offset(1).Value
            .Offset(, -1).Resize(n).Value = dt
        End With
        Range("_date").Value = vbNullString
        t_input.DataBodyRange.Delete
        MsgBox "Les données ont été archivées.", 64, "Information"
    End If

End Sub

Bonjour Jean-Eric,

Merci bcp pour cette suggestion. Ça fonctionne bien

Personnellement je n'ai pas pensé à utiliser un TCD car j'ai remarqué que les TCD augmentent beaucoup la taille du fichier et il faut toujours ajouter le code pour rafraichir le TCD.

Ton code est simple et il fonctionne bien alors merci pour le temps que tu as passé. Je vais adapter ton code à un tableau comportant plusieurs données et je vais voir si la taille du fichier augmente beaucoup

Tout le monde, si vous avez une idée sans TCD n'hésitez pas à la partager sinon le code de Jean-Eric est génial