Protection de feuille + macro

Bonjour à tous,

Je suis bloqué par "protection de feuille" qui empêche le bon fonctionnement du macro.

Ma "Feuille2" est protégé par un mot de passe qui est 1234, et mes données de ma "Feuille1" sont transmis vers "Feuille2" de avec ce macro.

Tandis que quand je vais ôter la protection tout fonctionne mais je souhaite garder le mot de passe ou la protection de ma "Feuille2" afin qu'il soit consultable et qu'il ne pourra être modifier.

Merci d'avance.

Bonjour,
Une proposition à adapter.
Cdlt.

Sub Macro1_TD()
Dim lo As ListObject, arr(2), r As Range

    With ActiveSheet
        arr(0) = .Range("C6").Value
        arr(1) = .Range("C10").Value
        arr(2) = .Range("C14").Value
    End With

    Set lo = Range("t_produits").ListObject
    Worksheets(lo.Parent.Name).Unprotect Password:=PWD

    With lo
        If .InsertRowRange Is Nothing Then
            Set r = .HeaderRowRange.Cells(1).Offset(.ListRows.Count + 1)
        Else
            Set r = .InsertRowRange.Cells(1)
        End If
    End With

    r.Resize(, 3).Value = arr

    With lo
        .Sort.SortFields.Add .ListColumns(1).DataBodyRange, xlSortOnValues, xlAscending
        .Sort.Header = xlYes
        .Sort.Apply
        .Sort.SortFields.Clear
    End With

    Worksheets(lo.Parent.Name).Protect Password:=PWD, userinterfaceonly:=True

    ActiveSheet.Range("C6,C10,C14").ClearContents

End Sub

Bonsoir,

Un tout grand Merci!

Cordialement,

Thibet