Valeur de la dernière cellule d'une ligne d'un tableau et recherche X
Bonjour,
Dans le fichier en PJ, à l'onglet "PREVISIONNEL AVANCEMENT REHAB", j'ai mis le prévisionnel de stade de facturation mois par mois.
Aussi, dans la colonne Q, je souhaite calculer, en fonction de la valeur de la dernière cellule de chaque ligne du tableau de cet onglet, que la valeur à facturer apparaisse (en allant chercher la donnée dans l'onglet Liste).
Par exemple pour la ligne 2, le résultat de la formule devrait être de 100 % car la dernière cellule remplie de cette ligne affiche "Bilan final" qui correspond à une facturation cumulée de 100 %.
Ainsi, dès que je fais une modification sur l'avancement, çà se calcule automatiquement
Pour la ligne 3, on a PRO qui correspond à 50 % ...
Une fois celà fait, dans l'onglet "Données opérations REHAB", à la colonne U, il faudrait que la valeur qui apparait corresponde au stade de facturation suivant ce qui apparaît en colonne R.
Exemple pour la ligne 28 "USINE A VETYVER" : ma formule ne met rien , alors qu'il devrait y avoir PRO (qui correspond à un pourcentage d'avancement cumulé de 50 %)
çà fait beaucoup met j'ai cherché au moins une heure, je ne comprends pas pourquoi ma recherche X ne fonctionne pas.
Merci de votre aide.
Bonjour à tous,
Sauf que ton resultat, c'est 0,999999417711583, et ce n'est pas 1 ==>tu ne peux pas le trouver en correspondance exacte. Tu dois donc changer le parametre de correspondance et le passer a 1.
Ou alors passer la colonnes R avec des arrondis pour avoir des valeurs entiéres.
Crdlmt
Bonjour à tous,
Une proposition ?
En Q2 :
=RECHERCHEX(INDEX(Prévisionnel_REHAB[@[JANVIER]:[DECEMBRE]];EQUIV("zzz";Prévisionnel_REHAB[@[JANVIER]:[DECEMBRE]];1));Avancement;Listes!$C$1:$C$15)En U2 :
=RECHERCHEX(ARRONDI(R2*100;0)/100;Listes!$C$1:$C$15;Avancement;"";0;-1)Hello JFL,
Pure curiosité, tu mets comment les fonctions en bleu etc dans ce message ?
Je te remercie d'avance :)
bonjour, merci pour votre aide, les formules fonctionnement pour ce qui concerne la REHAB
mais pour les projets en NEUF (onglet PREVISIONNEL AVANCEMENT NEUF), la formule ne fonctionne pas.
j'ai pourtant remis la même chose, la seule nuance est au niveau de la liste (un échelonnement différent selon que l'on est en NEUF PROPRE Listes!$C$19:$C$34, ou en VEFA Listes!$C$37:$C$50
mais je n'ai que de mauvais résultats
De plus, je souhaite mettre une formule automatisant la liste à choisir en fonction de ce qui est renseigné en colonne Type :
- si Type = Propre, choisir Listes!$C$19:$C$34
- si type = VEFA, choisir Listes!$C$37:$C$50
merci de votre aide
Bonjour à tous !
Une réaction après deux mois....
Vous faites un mauvais usage de la fonction RECHERCHEX.
En modifiant la plage concernant le tableau de recherche, cela fonctionne parfaitement.
J'ai ajouté la fonction SIERREUR pour parer les éventuelles lignes vides (de janvier à décembre).
La formule (en R2 de l'onglet PREVISIONNEL AVANCEMENT NEUF) que je vous propose de tester est donc :
=SIERREUR(RECHERCHEX(INDEX(Prévisionnel_NEUF[@[JANVIER]:[DECEMBRE]];EQUIV("zzz";Prévisionnel_NEUF[@[JANVIER]:[DECEMBRE]];1));Avancement_Propre;Listes!$C$19:$C$34);"")oui j'étais sur le feu sur d'autres sujets ...
merci pour votre formule, du coup est-il possible de rajouter une condition tenant au type Propre ou VEFA
En effet, quand la dernière cellule contient OS, pour une VEFA, le pourcentage qui doit apparaître est 50 % et non 65 % (qui correspond au type NEUF) ?
Bonjour de nouveau !
Quel "barème" doit-on appliquer si la dernière cellule est différente de "OS" ? Propre ou VEFA ?
le barême à appliquer dépend de ce qui est indiqué en colonne Type
Exemple pour la ligne VEFA LA ROSERAIE
Si la colonne B "Type" contient VEFA, que la dernière cellule renseignée entre les colonnes D et O contient OS, alors le pourcentage devant figurer en colonne R sera 50 %, qui correspond à la valeur se trouvant en cellule C41 de l'onglet "Listes" du tableau VEFA
En revanche, Si la colonne B "Type" contient propre, que la dernière cellule renseignée entre les colonnes D et O contient OS, alors le pourcentage devant figurer en colonne R sera 65 %, qui correspond à la valeur se trouvant en cellule C26 de l'onglet "Listes" du tableau Propre
Bonjour de nouveau !
Je vous remercie de ces précisions, qui confortent ma compréhension de votre besoin, mais vous n'apportez pas réponse à mon questionnement :
Quel "barème" doit-on appliquer si la dernière cellule est différente de "OS" ? Propre ou VEFA ?
la dernière cellule d'une ligne (valeur en colonne O) peut prendre n'importe quelle valeur du menu déroulant, donc si à la place d'OS il est écrit par exemple "Plâtres" :
- si le type est Propre : 90 %
- si le type est VEFA : 85 %
et ainsi de suite
Bonjour de nouveau !
Si la valeur de la dernière cellule de la ligne n'est pas un critère dans le choix du type de liste, je vous propose de tester la formule suivante :
=LET(
ca_;INDEX(Prévisionnel_NEUF[@[JANVIER]:[DECEMBRE]];EQUIV("zzz";Prévisionnel_NEUF[@[JANVIER]:[DECEMBRE]];1));
la_;"Avancement_" &[@Type];
pa_;SI([@Type]="Propre";Listes!$C$19:$C$34;Listes!$C$37:$C$50);
SIERREUR(RECHERCHEX(ca_;INDIRECT(la_);pa_);"")
)ben écoute, çà marche nickel
je ne connaissais pas cette fonction LET.
je te remercie beaucoup !
du coup je reviens sur la réponse ci-dessous de JFL - finalement elle ne fonctionne pas totalement (concerne l'onglet "Prévisionnel avancement REHAB")
En effet, à partir du stade 20 %, et jusqu'au stade 95 %, les valeurs ne renvoient que la correspondance de cumul à 65 %
Par exemple, si la dernière cellule renseignée contient 20 %, en colonne Q il devrait me renvoyer 70 %, mais il renvoit 65 %.
j'ai rajouté en colonne R la valeur qui devrait être renvoyée.
franchement je ne vois pas d'où vient le problème.
"Bonjour à tous,
Une proposition ?
En Q2 :
=RECHERCHEX(INDEX(Prévisionnel_REHAB[@[JANVIER]:[DECEMBRE]];EQUIV("zzz";Prévisionnel_REHAB[@[JANVIER]:[DECEMBRE]];1));Avancement;Listes!$C$1:$C$15)En U2 :
=RECHERCHEX(ARRONDI(R2*100;0)/100;Listes!$C$1:$C$15;Avancement;"";0;-1)Bonjour à tous !
du coup je reviens sur la réponse ci-dessous de JFL - finalement elle ne fonctionne pas totalement (concerne l'onglet "Prévisionnel avancement REHAB")
En effet, à partir du stade 20 %, et jusqu'au stade 95 %, les valeurs ne renvoient que la correspondance de cumul à 65 %
Par exemple, si la dernière cellule renseignée contient 20 %, en colonne Q il devrait me renvoyer 70 %, mais il renvoit 65 %.
Faute d'adapter la formule à son contexte, le retour ne peut qu'être erroné !
Initialement, la recherche de la dernière cellule occupée ne s’intéressait qu'aux valeurs textes.Hors ici, il convient de prendre en considération les valeurs numériques.
En conséquence, je vous propose de tester la formule suivante :
=RECHERCHEX(RECHERCHEX("?*";Prévisionnel_REHAB[@[JANVIER]:[DECEMBRE]]&"";Prévisionnel_REHAB[@[JANVIER]:[DECEMBRE]];;2;-1);Avancement;Listes!$C$1:$C$15)merci beaucoup, je n'aurai vraiment jamais trouvé
je ne connais pas l'expression "?*" pour rechercher et du texte, et des chiffres
Bonjour de nouveau !
Parfait !
je ne connais pas.......
Apprendre..... encore et encore. Jubilatoire non ?