Liste des no d'items à partir d'un dossier de fichiers pdf

Bonjour, j'ai besoin de votre aide. J'ai un dossier de 1154 fichiers pdf qui contiennent tous un no d'item de format spécifique de T0000001 AU T0009999

Est ce que quelqu'un a une idée d'un code dans VBA qui permettrait de sortir en format texte la liste des nos d'items que je pourrai ensuite copier dans Excel? je suis débutante dans ce programme et je pense que je serai capable de comprendre avec votre aide svp.

Bonjour Oum

Qu'est-ce qui contient le numéro d'item

Le nom du fichier ou le contenu du PDF !?

A+

le nom du fichier contient du texte et le no d'item y est inclus, il n'est pas nécessairement au début ni à la fin mais il est obligatoirement dedans.

Bonsoir Oum,

Voici peut-être un code qui fera l'affaire, à tester

Option Explicit

Sub ListeItem()
  Dim sPath As String, sFic As String, sItem As String
  Dim Lig As Long
  ' Chemin initiale
  sPath = "C:\Temp\"
  sFic = Dir(sPath & "*.pdf")
  Do While sFic <> ""
    With ActiveSheet
      ' Prochaine ligne vide
      Lig = .Range("A" & Rows.Count).End(xlUp).Offset(1, 0).Row
      ' Récupérer et inscrire le numéro d'item
      sItem = TrouveNum(sFic)
      If sItem <> "" Then .Range("A" & Lig).Value = sItem
    End With
    ' fichier suivant
    sFic = Dir
  Loop
End Sub

Function TrouveNum(sNomFic As String)
  Dim Ind As Integer, NbCar As Integer
  TrouveNum = ""
  ' Parcourir toute la chaine de caractères à la recherche du 1er chiffre
  For Ind = 1 To Len(sNomFic)
    ' Trouver début du numéro d'item
    If IsNumeric(Mid(sNomFic, Ind, 1)) Then
      ' récupère l'ensemble
      TrouveNum = "T" & Mid(sNomFic, Ind, 7)
      ' Sort
      Exit Function
    End If
  Next Ind
End Function

A+

Je vais le tester et vous confirmer, je vous remercie infiniment.

Bonjour,

Mon partenaire de projet a testé et ça fonctionne, sorry on avait mis de côté cette partie du projet d'où mon retard.

Tks a lot