Supprimer des lignes avec condition (VBA)

bonjour le forum

je veux utiliser un code vba pour supprimer une ligne si le taux < 60%

la condition du taux se situe dans la cellule H

tableau - range ("A2-M1800")

J'ai 1800 lignes

MON OBJECTIF est de supprimer toutes les lignes avec cette condition

merci d'avance

CODE mais ça ne fonctionne pas :

Sub Supprime()
For Each cellule In Range("A2:M1605")
If Range("H7") < 0.65 Then Rows(cellule.Row).Delete
Next
End Sub

Bonjour asta,

Pour supprimer des lignes on commence toujours par la fin en remontant avec une boucle For
Sinon il Faut utiliser Do... Loop

De plus vous n'avez pas mis de variable dans la cellule testée, c'est donc toujours la même : H7

Voici un code qui devrait fonctionner

Sub SupprimeTxInf()
  Dim dLig as long, Lig as long
  dLig = range("A" & Rows.Count).end(XlUp).Row
  For Lig = dLig to 2 Step - 1
    If Range("H" & Lig) < 0.65 then Range("A" & Lig).EntireRow.Delete
  Next Lig
End Sub

A+

Bonjour à tous,

Une autre solution avec neutralisation du calcul :

Sub Supprime()

Dim I As Integer

    With Application
         .ScreenUpdating = False
         .Calculation = xlCalculationManual
    End With

    For I = 1605 To 2 Step -1
        If Cells(I, "H") < 0.65 Then Cells(I, "H").EntireRow.Delete
    Next I

    With Application
         .ScreenUpdating = True
         .Calculation = xlCalculationAutomatic
    End With

End Sub

ça marche merci

Re,