RechercheV automatique

Question

Bonjour Forum, je sollicite votre aide sur excel, je veux dire à excel d'appliquer la formule RechercheV et trier par les #N/A, et copier en suite les matricules et Années pour les coller dans la Feuile1 selon l'ordre décris. j'ai utilisé une macro mais elle s'applique juste pour la première année, je veux que cette tâche s'applique pour les autres années aussi . Merci d'avance...

ThauThème · Answer

Bonjour Jani, bonjour le forum,

Pas sûr d'avoir bien compris... Je te propose le code ci-dessous qui ferait tout-en-un :

Sub Macro1()
Dim O1 As Worksheet 'déclare la variable O1 (Onglet 1)
Dim O2 As Worksheet 'déclare la variable O2 (Onglet 2)
Dim T1 As ListObject 'déclare la variable T1 (Tableau Structuré 1)
Dim T2 As ListObject 'déclare la variable T2 (Tableau Structuré 2)
Dim TV1 As Variant 'déclare la variable TV1 (Tableau des Valeurs 1)
Dim TV2 As Variant 'déclare la variable TV2 (Tableau des Valeurs 2)
Dim COL As Integer 'déclare la variable COL (COLonne)

Set O1 = Worksheets("Feuil1") 'définit l'onglet O1
Set O2 = Worksheets("Nouveaux Maricules") 'définit l'onglet O2
Set T1 = O1.ListObjects(1) 'définit le tableau structuré T1
Set T2 = O2.ListObjects(1) 'définit le tableau structuré T2
COL = T1.HeaderRowRange.Find(T2.HeaderRowRange(1, 2).Value, , xlValues, xlWhole).Column 'définit la colonne COL
TV1 = T1.DataBodyRange 'définit le tableau des valeurs TV1
TV2 = T2.DataBodyRange 'définit le tableau des valeurs TV2
For I = 1 To UBound(TV1, 1) 'boucle 1 : sur toutes les lignes I du tableau des valeurs TV1
    For J = 1 To UBound(TV2, 1) 'boucle 2 : sur toutes les lignes J du tableau des valeurs TV2
        If TV1(I, 1) = TV2(J, 1) Then 'si la donnée ligne I colonne 1 de TV1 est égale à la donnée ligne J colonne 1 de TV2
            'recupère dans les données de T1, ligne I colonne COL, la valeur de la ligne J colonne 2 des données de T2
            T1.DataBodyRange(I, COL) = T2.DataBodyRange(J, 2)
            Exit For 'sort de la boucle 2
        End If 'fin de la condition
    Next J 'prochaine ligne de la boucle 2
Next I 'prochaine ligne de la boucle 1
End Sub