Mise à jour cellules nommées dans macros suite à conversion de xls en xlsm

Question

Comme indiqué dans le titre, j'ai converti un ancien fichier xls (contenant des macros) en xlsm. J'ai environ 70 cellules (ou plages) nommées du style "chf1", "chf2", "chf3", "LL1", etc… qui ont été renommées en "_chf1", "_chf2", "_chf3", "_LL1". Jusque-là, tout est tout à fait normal. Le problème est que ces noms n'ont pas été modifiés dans les macros. Il faut maintenant que je le fasse à la main et il y en a beaucoup. De plus, mon fichier appelle des macros situées dans des classeurs externes. Y-aurait-il moyen de créer une boucle qui parcourt toutes les plages nommées concernées de tous les classeurs ? Je ne vois pas trop comment m'y prendre et j'aimerai éviter de le faire une par une dans chaque classeur. Auriez-vous une idée à me proposer pour accélérer le traitement et surtout éviter de générer des erreurs en effectuant de faux remplacements ou en oublier ? D'avance merci pour votre aide. Boris...

Eric Kergresse · Accepted Answer

Le code ci-dessous recense les zones nommées dans un module et les note dans un onglet "Zones nommées"

Sub TestDetecterZoneNommeeModule()

    DetecterZoneNommeeModule Sheets("Zones nommées"), "Module1"

End Sub

Sub DetecterZoneNommeeModule(ByVal Sh As Worksheet, NomModule As String)

Dim x As Integer, LigneEnCours As Integer
Dim Texte As String, strVar As String

    LigneEnCours = 2
   With ThisWorkbook.VBProject.VBComponents(NomModule).CodeModule
          For x = 1 To .CountOfLines
             Texte = .Lines(x, 1)
             If InStr(1, Texte, "Range", vbTextCompare) > 0 Then
                Sh.Cells(LigneEnCours, 1) = Texte
                LigneEnCours = LigneEnCours + 1
             End If
          Next x
    End With

End Sub

Vous allez récupérer les données comme ceci :

Une fois les zones mises dans un tableau structuré t_Zones

Le code ci-dessous met à jour les lignes de code :

Option Explicit
Option Compare Text

Sub TestRemplacerZoneNommeeModule()

Dim AireZones As Range

     Set AireZones = Range("t_Zones[Ancien]")
     RemplacerZoneNommeeModule "Module1", AireZones
     Set AireZones = Nothing

End Sub

Sub RemplacerZoneNommeeModule(ByVal NomModule As String, ByVal AireZones2 As Range)

Dim x As Integer, Y As Integer
Dim Texte As String, strVar As String, ZoneAvant As String, ZoneApres As String

   With ThisWorkbook.VBProject.VBComponents(NomModule).CodeModule
          For x = 1 To .CountOfLines
             Texte = .Lines(x, 1)
             For Y = 1 To AireZones2.Count
                  ZoneAvant = "Range(""" & AireZones2(Y).Value & """)"
                  ZoneApres = "Range(""" & AireZones2(Y).Offset(0, 1).Value & """)"

                 If InStr(1, Texte, ZoneAvant, vbTextCompare) > 0 Then
                    strVar = Application.WorksheetFunction.Substitute(Texte, ZoneAvant, ZoneApres)
                    .ReplaceLine x, strVar
                    Exit For
                 End If
             Next Y
          Next x
    End With

End Sub

Il vous faut ensuite adapter ce code pour balayer tous les modules.

Eric Kergresse · Answer

Il serait peut-être plus simple de rebaptiser les zones avec leur nom d'origine, non ...

Valentin85 · Answer

Avec Ctrl + H cela n'est pas possible ? ou bien c'est trop long ...

Eric Kergresse · Answer

Comment se présente une procédure à modifier ? Avec ancien et nouveau nom...

Eric Kergresse · Answer

Pour faire l'inventaire des zones nommées : Sub ListerLesZonesNommees() Dim LigneTitreZone As Long, DerniereLigneZNommee As Long Dim Wb As Workbook Dim ShListesZones As Worksheet Dim MaZoneNommee As Name Set ShListesZones = ThisWorkbook.Sheets.Add Set Wb = Workbooks("XXXXX.xlsm") ' A adapter With ShListesZones .Cells.Clear LigneTitreZone = 10 DerniereLigneZNommee = LigneTitreZone + 1 With .Range(.Cells(LigneTitreZone, 1), .Cells(LigneTitreZone, 2)) .Value = Array("Nom", "Adresse") .Interior.Color = RGB(255, 255, 0) .Font.Bold = True End With For Each MaZoneNommee In Wb.Names .Cells(DerniereLigneZNommee, 1).Value = MaZoneNommee.Name .Cells(DerniereLigneZNommee, 2).Value = "'" & MaZoneNommee.RefersTo DerniereLigneZNommee = DerniereLigneZNommee + 1 Next MaZoneNommee End With Set ShListesZones = Nothing Set Wb = Nothing End Sub...