Sélection d'une colonne à partir d'une variable

Question

J'essaie d'écrire une macro VBA pour calculer le max d'une variable à partir de la fonction Application.WorksheetFunction.MaxIfs J'ai un tableau avec les colonnes Référence, Itération. J'ai nommé deux variables : numeroColonneRef et numeroColonneIteration. Dans un premier temps je fais une boucle For : For j = 1 To derniereColonne (je calcule la derniere colonne dans mon code) If Worksheets("DataBase").Cells(1, j) = "Itération" Then numeroColonneIteration = j End If If Worksheets("DataBase").Cells(1, j) = "Référence" Then numeroColonneRefExterne = j End If Next Je fais cette boucle pour avoir des colonnes qui peuvent bouger et donc avoir une macro qui s'adapte malgré le déplacement des colonnes. IterationMaxJalon = Application.WorksheetFunction.MaxIfs(Range(Columns(numeroColonneIteration)), Range(Columns(numeroColonneRefExterne)), Worksheets("Database").Cells(i, numeroColonneRefExterne)) Pour chaque ligne de mon tableau je voudrais calculer le max de l'itération pour une référence donnée. Par exemple, si j'ai trois lignes dans mon tableau avec une référence A et respectivement 1, 2 et 3 dans la colonne itération, je souhaiterais que IterationMaxJalon = 3. Lorsque je fais tourner mon code, j'ai l'erreur suivante : La méthode Range de l'objet Global a échoué. J'imagine que j'ai mal écris Range(Columns(i)) mais je ne vois pas ce qui bloque. Pouvez vous m'aider s'il vous plaît ...

ThauThème · Answer

Bonjour Exia, bonjour le forum,

Désolé mais j'ai du mal avec les variables trop longues... Essaie comme ça :

Dim O As Worksheet
Dim DC As Integer
Dim J As Integer
Dim NC As Integer
Dim NCRE As Integer

Set O = Worksheets("DataBase")
DC = O.Cells(1, Application.Columns.Count).End(xlToLeft).Column
For J = 1 To DC
    If O.Cells(1, J) = "Itération" Then NC = J
    If O.Cells(1, J) = "Référence" Then NCRE = J
Next
MsgBox "Itération : " & NC & ", Référence : " & NCRE
IterationMaxJalon = Application.WorksheetFunction.MaxIfs(O.Range(O.Cells(1, NC), O.Cells(1, NCRE)).EntireColumn, O.Cells(i, numeroColonneRefExterne))

ThauThème · Answer

Bonjour Exia, Sans le code complet où l'on sait ce que valent les variables, on ne peut pas t'aider. L'idéal serait ton fichier ou un fichier exemple anonymisé basé sur ton fichier original...

Jean-Paul · Answer

Ha le fameux Exit For... Si tu fais un Exit For comme son nom l'indique tu sort de la boucle que tu sois à 2, 3, ou 15 tu sort sans vérifier les suivants. Il faut éviter autant que faire ce peut ce type de programmation, et préférer des Select Case ou Bloc If. Et comme le dit si bien @ThauThème sans fichier exemple.....

ThauThème · Answer

Bonjour le fil, bonjour le forum,

Exia, tu ne vois peut-être pas en quoi ça peut aider, mais ça nous permet tout simplement de tester sans avoir a recréer ton environnement.

Ton code me paraît correct mais il y a une erreur de variable :

For j = 1 To derniereColonne
    If Worksheets("DataBase").Cells(1, j) = "ID" Then
        numeroColonneID = j
    End If

Next

For j = 1 To derniereColonne
    If Worksheets("Extraction").Cells(4, j) = "ID" Then
        numeroColonneID2 = j
    End If
Next

La deuxième boucle devrait avoir comme variable derniereColonne2. Ça arrive avec des noms de variable peu explicites...

Une autre proposition :

Sub NouveauxDocs()
Dim OD As Worksheet 'déclare la variable OD (Onglet Database)
Dim OE As Worksheet 'déclare la variable OE (Onglet Extraction)
Dim CIDD As Integer 'déclare la variable CIDD (Colonne ID Database)
Dim CIDE As Integer 'déclare la variable CIDE (Colonne ID Extraction))
Dim DLE As Long 'déclare la variable DLE (Dernière Ligne Extraction)
Dim I As Long 'déclare la variable I (Incrément)
Dim R As Range 'déclare la variable R (Recherche)
Dim DEST As Range 'déclare la variable DEST (cellule de DESTination)

Set OD = Worksheets("DataBase") 'définit l'onglet OD
Set OE = Worksheets("Extraction") 'définit l'onglet OE
CIDD = OD.Rows(1).Find("ID", , xlValues, xlWhole).Column 'définit la colonne CIDD contenant ID dans la lignne 1 de l'onglet Database
CIDE = OE.Rows(4).Find("ID", , xlValues, xlWhole).Column 'définit la colonne CIDE contenant ID dans la ligne 4 de l'onglet Extraction
DLE = OE.Cells(Application.Rows.Count, CIDE).End(xlUp).Row 'définit la dernière ligbne éditée DLE de la colonne CIDE de l'onglet Extraction

For I = 5 To DLE 'boucle sur toutes les lignes éditées I de l'onglet Extraction (en partant de la cinquième)
    'définit la recherche R (recherche la valeur entière de la cellule ligne I colonne CIDE
    'de l'onglet Extraction dans la colonne CIDD de l'onglet DataBase
    Set R = OD.Columns(CIDD).Find(OE.Cells(I, CIDE), , xlValues, xlWhole)
    If R Is Nothing Then 'condition : si aucune occurrence trouvée
        'définit la cellule de destination DEST (première cellule vide de la colonne CIDD de l'onglet DataBase)
        Set DEST = OD.Cells(Application.Rows.Count, CIDD).End(xlUp).Offset(1, 0)
        OE.Cells(I, CIDE).Copy DEST 'copie la cellule ligne I colonne CIDE de l'onglet Extraction et la colle dans DEST
    End If 'fin de la condition
Next I 'prochaine ligne de la boucle
End Sub

ThauThème · Answer

Re,

Si tu ne lis pas les réponses on ne s'en sortira pas... Pourquoi ça ne fonctionne pas ? Parce que mauvaise variable dans la boucle 2.

Sinon, toujours la même réponse... Le fichier qui va bien et des explications claires basées sur ce fichier...

ThauThème · Answer

Re, Tu n'as même pas daigné jeter un coup d'œil au code que je t'avais proposé. Ou, en tous cas, tu n'as fait aucun commentaire... Désolé mais devant tant de désinvolture, je passe la main.....

ThauThème · Answer

Bonjour le fil, bonjour le forum,

Tu as raison Exia, ton cod, même avec la variable renommée, ne fonctionne toujours pas. Pourquoi ? Je t'avoue que je ne sais pas. Comme tu utilises une méthode qui ne me convient pas, je t'ai proposé une autre solution. Je comprends aussi que cette proposition ne te convienne pas non plus mais je ne peux plus rien pour toi.

Sache quand même que VBE (l'éditeur de VBA) propose une option Rechercher/Remplacer ([CTRL]+[H]) qui en quelques clics te permet de remplacer les noms des variables...

Bonne chance.

ThauThème · Answer

Bonjour Exia, bonjour le forum,

Désolé pour le retard mais je suis peu disponible en ce moment.

Essaie comme ça (3 changements notés "<------ ICI", dans la code)

Sub NouveauxDocs()

Dim OD As Worksheet 'déclare la variable OD (Onglet Database)
Dim OE As Worksheet 'déclare la variable OE (Onglet Extraction)
Dim CIDD As Integer 'déclare la variable CIDD (Colonne ID Database)
Dim CIDE As Integer 'déclare la variable CIDE (Colonne ID Extraction))
Dim DLE As Long 'déclare la variable DLE (Dernière Ligne Extraction)
Dim DCE As Integer 'déclare la variable DCE (Dernière Colonne Extactoin)
Dim I As Long 'déclare la variable I (Incrément)
Dim R As Range 'déclare la variable R (Recherche)
Dim DEST As Range 'déclare la variable DEST (cellule de DESTination)  <------------- ICI

Set OD = Worksheets("DataBase") 'définit l'onglet OD
Set OE = Worksheets("Extraction") 'définit l'onglet OE
CIDD = OD.Rows(1).Find("ID", , xlValues, xlWhole).Column 'définit la colonne CIDD contenant ID dans la lignne 1 de l'onglet Database
CIDE = OE.Rows(4).Find("ID", , xlValues, xlWhole).Column 'définit la colonne CIDE contenant ID dans la ligne 4 de l'onglet Extraction
DLE = OE.Cells(Application.Rows.Count, CIDE).End(xlUp).Row 'définit la dernière ligbne éditée DLE de la colonne CIDE de l'onglet Extraction
DCE = OE.Cells(4, Application.Columns.Count).End(xlToLeft).Column 'définit la dernière colonne éditée DCE de la ligne 4 de l'onglet Extraction  <------------- ICI
For I = 5 To DLE 'boucle sur toutes les lignes éditées I de l'onglet Extraction (en partant de la cinquième)
    'définit la recherche R (recherche la valeur entière de la cellule ligne I colonne CIDE
    'de l'onglet Extraction dans la colonne CIDD de l'onglet DataBase
    Set R = OD.Columns(CIDD).Find(OE.Cells(I, CIDE), , xlValues, xlWhole)
    If R Is Nothing Then 'condition : si aucune occurrence trouvée
        'définit la cellule de destination DEST (première cellule vide de la colonne CIDD de l'onglet DataBase)
        Set DEST = OD.Cells(Application.Rows.Count, CIDD).End(xlUp).Offset(1, 0)
        OE.Range(OE.Cells(I, CIDE), OE.Cells(I, DCE)).Copy DEST 'copie la plage ligne I colonne CIDE à colonne DLE de l'onglet Extraction et la colle dans DEST  <------------- ICI
    End If 'fin de la condition
Next I 'prochaine ligne de la boucle
End Sub