Récupération de couleur

je m'explique dans mon userform j'ai c'est bouton d'option

qui selon sélection change la couleur du texte dans la textbox jusque la tout vas bien!youpies

apres remplissage de l'userform

et le click sur bouton qui enregistre le texte (Problem)

il execute mais le text dans la feuille de calcul reste noir

D'ou ma question comment faire apparaitre la couleur dans la feuille?

Private Sub TxtDescription_Change()
    If ObNoir.Value = True Then
    TxtDescription.ForeColor = &H80000012
     ElseIf OB_Bleu.Value = True Then
    TxtDescription.ForeColor = &HFF0000
     ElseIf OB_Rouge.Value = True Then
    TxtDescription.ForeColor = &HFF&
    ElseIf OB_Vert = True Then
    TxtDescription.ForeColor = &HC000&
 End If
End Sub

Private Sub Button_close_Click()
    Unload Me
End Sub

Private Sub Button_clear_Click()
    TBTime.Text = Format(Now(), "hh:mm AM/PM")
    CbEntrance.Value = ""
    CbSite.RowSource = "List!ListSite": CbSite.ListIndex = 0
    ObNoir.Value = True
End Sub

Private Sub Button_register_Click()
 If Len(Me.CbName) = 0 Then
    Me.LblError = "Enter a Name"
    Me.CbName.SetFocus
   Else
    Report.Activate
    Range("F1048576").End(xlUp).Offset(1, 0).Select
    ActiveCell.Value = ActiveCell.Offset(-1, 0) + 1
    ActiveCell.Offset(0, 1) = Me.TBTime.Value
    ActiveCell.Offset(0, 2) = Me.CBEvent.Value & " " & Me.CbName.Value & " by " & Me.CbEntrance.Value & "(" & CbCar.Value & ")"
    End If
End Sub

Bonjour Hizuky, bonjour le forum,

Le code c'est bien mais pour le tester il nous faut recréer ton problème et c'est pénible. Pense à fournir le fichier qui va bien dans ces cas là...

Sinon, j'aurais plutôt codé comme ça pour le changement de couleur et en plus ça facilite le report de couleur dans la ou les cellules :

Private C As Variant

Private Sub ObNoir_Click()
C = &H80000012: Call ChangeCoul
End Sub
Private Sub OB_Bleu_Click()
C = &HFF0000: Call ChangeCoul
End Sub
Private Sub OB_Rouge_Click()
C = &HFF&: Call ChangeCoul
End Sub
Private Sub OB_Vert_Click()
C = &HC000&: Call ChangeCoul
End Sub

Private Sub Button_close_Click()
    Unload Me
End Sub

Private Sub Button_clear_Click()
    TBTime.Text = Format(Now(), "hh:mm AM/PM")
    CbEntrance.Value = ""
    CbSite.RowSource = "List!ListSite": CbSite.ListIndex = 0
    ObNoir.Value = True
End Sub

Private Sub Button_register_Click()
If Len(Me.CbName) = 0 Then
    Me.LblError = "Enter a Name"
    Me.CbName.SetFocus
Else
    Report.Activate
    With Range("F1048576").End(xlUp).Offset(1, 0)
        .Font.Color = C 'ou .resize(1,3).Font.Color = C (pour les trois colonnes)
        .Value = .Offset(-1, 0) + 1
        .Offset(0, 1) = Me.TBTime.Value
        .Offset(0, 2) = Me.CBEvent.Value & " " & Me.CbName.Value & " by " & Me.CbEntrance.Value & "(" & CbCar.Value & ")"
    End With
End If
End Sub

Sub ChangeCoul()
Dim CTRL As Control

For Each CTRL In Me.Controls
    If TypeOf CTRL Is MSForms.OptionButton Then
        If CTRL.Value = True Then Me.TxtDescription.ForeColor = C: Exit For
    End If
Next CTRL
End Sub

bonjour merci pour ta réponse je test ca de suite

car marche nickel merci