Recuperer l'adresse des cellules contenant une chaine de caractere

Question

J aimerais savoir si il existe un moyen de lister l'adresse de toutes les cellules (ou lignes) d'une colonne, contenant une chaine de caracteres "toto1" sachant que dans chaque cellule il peut y avoir d'autre chaine de caractere. (toto2, totox, ...) Sans faire de fonction VBA ca me parait pas possible, qu'en pensez-vous ? ( j y ai passe 3h sans success ;-( ) Ensuite avec une Fonction VBA ? comment faire ? peut etre le sujet existe deja, (ca me parait classique comme probleme), je vous remercie pour votre aide. Cordialement...

tulipe_4 · Answer

Oui ,c'est faisable , mais il faut un fichier (pas une photo) cordialement...

ThauThème · Answer

Bonsoir le fil, bonsoir le forum,

Une proposition VBA à adapter :

Sub Macro1()
Dim O As Worksheet 'déclare la variable O (Onglet)
Dim DL As Long 'déclare la variable DL (Dernière Ligne)
Dim DC As Long 'déclare la variable DC (Dernière colonne)
Dim TV As Variant 'déclare la variable TV (Tableau des Valeurs)
Dim I As Integer 'déclare la variable I (Incrément)
Dim J As Integer 'déclare la variable J (incrément)
Dim MES As String 'déclare la variable MES (MESsage)

Set O = Worksheets("Feuil1") 'définit l'onglet O (à adapter à ton cas)
DL = O.UsedRange.SpecialCells(xlCellTypeLastCell).Row 'définit la dernière ligne DL de la plage éditée de l'onglet O
DC = O.UsedRange.SpecialCells(xlCellTypeLastCell).Column 'définit la dernière colonne DC de la plage éditée de l'onglet O
TV = O.Range(O.Cells(1, 1), O.Cells(DL, DC)) 'définit le tableau des valeurs TV
For I = 1 To UBound(TV, 1) 'boucle 1 : sur toutes les lignes I du tableau des valeurs TV
    For J = 1 To UBound(TV, 2) 'boucle 2 : sur toutes les colonnes J du tableau des valeurs TV
        'si le texte de la donnée ligne I colonne J  de TV contient "toto1"
        If InStr(1, TV(I, J), "toto1", vbTextCompare) <> 0 Then
            'définit le message MES
            MES = IIf(MES = "", "Toto1 se trouve : " & vbCrLf & "Ligne " & I & ", colonne " & J, MES & vbCrLf & "Ligne " & I & ", colonne " & J)
        End If 'fin de la condition
    Next J 'prochaine colonne de la boucle 2
Next I 'prochaine ligne de la boucle 1
MsgBox MES 'affiche le message MES
End Sub

tulipe_4 · Answer

Une contribution sans vba...