Excel VBA saut de Page

Bonjour,

A tester :

Sub TestGenererDesSautDePage()

    GenererDesSautDePage ActiveSheet

End Sub
Sub GenererDesSautDePage(ByVal Sh As Worksheet)

Dim I As Long, DerniereLigne As Long

    With Sh
         DerniereLigne = .Cells(.Rows.Count, 1).End(xlUp).Row
         For I = .HPageBreaks.Count To 1 Step -1
             .HPageBreaks(I).Delete
         Next I
         For I = DerniereLigne To 2 Step -1  ' A ajuster en fonction de la ligne de titre
             If WorksheetFunction.CountA(.Cells(I, 1).EntireRow) = 0 Then
                .HPageBreaks.Add Before:=.Cells(I + 1, 1)
             End If
         Next I
    End With

End Sub

Où est votre fichier ?

Le formatage de votre impression n'est pas correct. Regardez la mise en page dans le fichier joint.

En ce qui concerne les sauts de page, j'ai ajouté le mot "Saut" en début de chaque bloc en colonne A.

Le code est le suivant :

Les macros sont lancés à partir des deux boutons dans la barre d'accès rapide. Curieusement je n'ai pu modifier les icônes comme je le fais d'habitude.

Option Explicit

Sub TestGenererDesSautsDePage()

    GenererDesSautDePage ActiveSheet
    MsgBox "Fin de création des sauts de page !", vbInformation

End Sub

Sub GenererDesSautDePage(ByVal Sh As Worksheet)

Dim I As Long, DerniereLigne As Long

    With Sh
         DerniereLigne = .Cells(.Rows.Count, 1).End(xlUp).Row
         If .HPageBreaks.Count > 0 Then
            For I = .HPageBreaks.Count To 1 Step -1
                .HPageBreaks(I).Delete
            Next I
         End If
         For I = DerniereLigne To 4 Step -1
             If .Cells(I, 1) = "Saut" Then
                .HPageBreaks.Add Before:=.Cells(I, 1)
             End If
         Next I
    End With

End Sub

Sub TestSupprimerLesSautsDePage()

    SupprimerLesSautsDePage ActiveSheet
    MsgBox "Fin de suppression des sauts de page !", vbInformation

End Sub

Sub SupprimerLesSautsDePage(ByVal Sh As Worksheet)

Dim I As Long

    With Sh
         For I = .HPageBreaks.Count To 1 Step -1
             .HPageBreaks(I).Delete
         Next I
    End With

End Sub

re bonjour,

j'ai essayé en mettant le code sur mon fichier, mais j'ai des erreurs...
Pouvez-vous me renvoyer le fichier mais en xls svp ?

Bonjour,

Vous pourriez également le faire en sauvegardant sous Excel 97 - 2003.

Vos paramètres de mise en page n'étaient pas correctement réglés, regardez dans les fichiers que je vous ai envoyés.

Essayez de passer en mode Affichage avec saut de page.

Essayez également de neutraliser d'abord la suppression des sauts de page dans la procédure "GenererLes.."

Cela me l'a fait également, c'est comme si VBa ne reconnaissait pas la collection existante. Il faut neutraliser la destruction, générer les sauts de pages et remettre le code comme avant.

Ce sont les apostrophes qu'on met devant les lignes de code. Celles-ci passent en vert et deviennent des commentaires :

Sub GenererDesSautDePage(ByVal Sh As Worksheet)

Dim I As Long, DerniereLigne As Long

    With Sh
         DerniereLigne = .Cells(.Rows.Count, 1).End(xlUp).Row
       '  If .HPageBreaks.Count > 0 Then
       '     For I = .HPageBreaks.Count To 1 Step -1
       '         .HPageBreaks(I).Delete
       '     Next I
       '  End If
         For I = DerniereLigne To 4 Step -1
             If .Cells(I, 1) = "Saut" Then
                .HPageBreaks.Add Before:=.Cells(I, 1)
             End If
         Next I
    End With

End Sub

??? C'est dans mon dernier message.

Est-ce que cela fonctionne dans les fichiers que je vous ai envoyés ?