Sommes des lignes Erreur d'exécution '6' ; Dépassement de capacité

Merci !

Mais je rencontre un problème : c'est un truc de folie !

Dans le fichier que je t'ai fourni ; j'ai testé la macro qui fonctionne super bien. C'est une copie de mon tableau origine pour garder les informations confidentielles. Il n'y absolument rien qui change à part le nom de la feuille et PAS MOYEN que cela fonctionne ; il me retourne toujours un bug comme ci-dessous (copie d'écran). A quoi cela peut être dû ? Je ne comprends vraiment pas, il y a le même nombre de colonne, au même endroit ... tout tout

bonjour,

c'est très probablement lié à tes données. il y a peut-être une donnée non valable (en erreur) dans ton tableau. Quel est le message d'erreur ?

J'ai trouvé ; effectivement c'est sur ma dernière ligne j'ai des étoiles.

Car il peut arriver que dans ma stat ; il y a des étoiles qui se mettent et pour éviter de filtrer et d'effacer ; on peut faire autrement ? ou passer cette étoile ou la convertir ?

Peut-on contourner ce problème ?

bonjour,

un façon de faire

Sub Sommes_Results_Lignes2()
 'Déclaration des variables
    Dim s1() ' s1 tableau qui contiendra les sommes à mettre en colonne L (performance !)
    Dim s2()     's2 tableau qui contiendra les sommes à mettre en colonne T (performance !)
    Dim t 't tableau qui contiendra une copie des données utiles de la feuille (performance !)
    Dim i As Long, j As Long, dl As Long

    With Sheets("feuil2") ' tous les objets dans les lignes qui suivent qui sont précédés d'un point appartiennent à cette feuille (range, cells)
        dl = .Range("H" & Rows.Count).End(xlUp).Row 'formule de codage ne pas toucher - Cette instruction donne la dernière ligne non vide sur base de la colonne H
        ReDim s1(1 To dl, 1 To 1), s2(1 To dl, 1 To 1) ''dimensionne les tableaux des sommes en fonction du nombre de lignes
        t = .Range("A1").Resize(dl, 9) 'copie les données utiles de la feuille dans le tableau t

        'on fait les calculs des sommes
        For i = 14 To dl 'on parcourt une à une les lignes de la ligne 14 à la dernière ligne
            For j = 5 To 6 'indique les colonnes qu'il doit prendre en compte pour la ligne
                s1(i - 13, 1) = s1(i - 13, 1) + Val(t(i, j)) ' on fait la somme dans s1 des cellules de la ligne i colonnes 5 à 6
                s2(i - 13, 1) = s2(i - 13, 1) + Val(t(i, j + 3)) ' on fait la somme dans s2 des cellules de la ligne i colonnes 8 à 9
            Next j 'prochaine colonne
        Next i 'prochaine ligne

        'les calculs sont terminés et sont stockés dans les tableaux s1 et s2

        .Range("G14").Resize(dl, 1) = s1 'on copie le tableau des sommes s1 en colonne G
        .Range("J14").Resize(dl, 1) = s2 'on copie le tableau des sommes s2 en colonne J

    End With
End Sub

Je ne sais pas ce que tu as modifié dans la macro mais ça fonctionne Merci

j'ai modifié les instructions d'addition s1 et s2