Chercher un dossier dans l'explorateur Windows et y copier des données

Bonjour,

A partir de mon fichier Excel Fichier1, qui contient des données, je veux ouvrir l'explorateur Windows, sélectionnez un fichier Excel, Fichier 2, dans un dossier et copier les données que j'ai dans Fichier 1 dans la feuille nommée "Feuille 2" du Fichier 2.

J'ai essayé de faire un code mais celui-ci ne fonctionne pas.

J'arrive à bien copier les valeurs du Fichier 1, à ouvrir et sélectionner le document dans l'explorateur Windows, mais je n'arrive pas à ouvrir la feuille "Feuille2" dans le fichier "Fichier2".

Sub transfert()
'
' Macro1 Macro
'
Dim strf As String
Dim objf As Object
Dim Fichier2 As Workbook
Dim Feuille2 As Worksheet

ActiveSheet.Select
Range("A3:F10").Select
Selection.Copy
'Copie les valeurs dans Fichier1

 Set objf = CreateObject("Shell.Application")
strf = "S:\VBA\Liste des Fichiers"
 ChDrive strf
 ChDir strf
objf.Open (strf)
'ouvre l'explorateur windows

Set Fichier2 = Application.Workbooks.Open(objf)
Set Feuille2 = Fichier2.Worksheets("feuille2")

Feuille2.Select
Range("B2:G10").Select
ActiveSheet.Paste
Fichier2.Save
Fichier2.Close
'Colle les valeurs dans Fichier2

End Sub

Merci de votre aide.

Bonne journée

bonjour,

une proposition (non testée)

Sub transfert()
    '
    ' Macro1 Macro
    '

    Dim Fichier2 As Workbook
    Dim Feuille2 As Worksheet, Feuille1 As Worksheet
    Dim nomfichier2 As String
    Set Feuille1 = ActiveSheet
    With Application.FileDialog(msoFileDialogFilePicker)
        .AllowMultiSelect = False
        .Title = "choisir fichier excel à ouvrir"
        .Filters.Clear
        .Filters.Add "Excel files", "*.XLS*"
        If .Show = True Then
            nomfichier2 = .SelectedItems(1)
        Else
            MsgBox "pas de fichier sélectionné"
            Exit Sub
        End If
    End With
    Set Fichier2 = Workbooks.Open(nomfichier2)
    Set Feuille2 = Fichier2.Sheets("feuille2")
    Feuille1.Range("A3:F10").Copy Feuille2.Range("B2:G10")
    Fichier2.Close
End Sub

Super !

Ca fonctionne.

Merci à vous,

Bonn journée