Besoin_d'aide_pour_une_Formule_N-1

Bonjour j'aimerai créer une formule afin de sélectionner tout les chiffre d'une colonne sauf la dernière qu'on vient d'ajouter... et si on ajoute a nouveau un montant que la formule prenne en compte tout les précèdent sauf le dernier ajouté...et ainsi de suite afin de pouvroi ajouter des chiffres et qu'il fasse le calcul des montant precedents seulement..

j'espère avoir été clair..

Merci

Bonjour Eddy_le, le forum,

Si tu veux sommer ta colonne B sans la dernière valeur....un exemple...

=SOMME(INDIRECT("B1:B"& EQUIV(9^9;B:B;1)-1))

[EDIT] : Oups ! Pas vu que c'était pour CALC

A tester:

=SOMME(INDIRECT("B1:B"& EQUIV(9^9;B$1:B$10485576;1)-1))

Cordialement,

Merci beaucoup c'est exactement ce que je veux, la formule =SOMME(INDIRECT("B1:B"& EQUIV(9^9;B:B;1)-1)) fonctionne bien,

Par contre j'aimerai ne cibler qu'entre les lignes 33 et 45 par exemple que dois-je faire ?

(CALC pas compris j'ai du me tromper la première réponses est parfaite)

Re,

Merci pour ton retour,

CALC pas compris

Tu as posté dans la section CALC au lieu d'EXCEL VBA...., j'ai alors supposé que tu utilisais OpenOffice.....

ne cibler qu'entre les lignes 33 et 45

=SOMME(INDIRECT("B33:B"&(EQUIV(9^9;B33:B45;1)+31)))

semble fonctionner, à vérifier, ça devient compliqué pour moi,

Cordialement,

Hello les amis !

SI ça devient trop compliqué, il y a la fonction décaler ^^

=SOMME(DECALER(B33;;;NBVAL(B33:B45)-1))

Re,

SI ça devient trop compliqué, il y a la fonction décaler ^^

Merci JoyeuxNoel ! Effectivement, c'est beaucoup plus propre que mon bricolage,

[EDIT] Je remarque toutefois que si seul B33 est rempli, on a une erreur #REF! car nbval = 1 , -1 = 0.

De même pour mon bricolage, si aucune valeur : #N/A que je peux corriger ainsi:

=SIERREUR(SOMME(INDIRECT("B33:B"&(EQUIV(9^9;B33:B45;1)+31)));0)

Amitiés,

Bon bah si c'est comme ça, je corrige aussi !

=sierreur(SOMME(DECALER(B33;;;NBVAL(B33:B45)-1));0)

Bonne remarque, cela dit 😉

Re,

Oui, effectivement, l'erreur est corrigée,

Je relève toutefois que nos résultats diffèrent:

Mais je crois que je me prends trop la tête , la logique voudrait qu'on remplisse à partir de B33 sans lignes vides,, il n'y a qu'un esprit tordu comme le mien pour faire autrement,

Encore merci ,

Bye.

Ah oui, bien entendu décaler ne fonctionne ici que si les données sont bien structurées, et sans lignes vides.

Sinon il faut effectivement passer par l'equiv, comme tu as fait 😁

Du coup je ne sais pas s'il n'est pas préférable de rester sur ta version, qui fonctionnera dans tous les cas...

Il faut dite que j'aime tellement cette fonction décaler... je l'utilise à toutes les sauces.

Olalal, je m'absente le temps d'un Week end et je retrouve 2 passionnés qui se sont acharnés sur mon souci, à cela je dit bravo et merci !!!!

Je test cette formule dans la matinée mais nul doute quelle est parfaite!

Un très grand merci a vous 2 en tout cas.

Bonne journée, semaine, fin d'année ;) !

Bon bon bon, j'ai testé vos 2 formules et celle de xorsankukai fonctionne bien par contre celle de JoyeuxNoel ne veut pas fonctionner (elle ne soustrait pas le dernier chiffre entré...)

Par contre j'ai encore une demande, il faudrait que lorsque je n'ai qu'un chiffre dans ma colonne il soit affiché 0 et pas le montant du seul chiffre :D

Vraiment merci beaucoup, j'ai essayé de comprendre la formule, mais WOW ! impossible je comprends rien -_-'

Bonjour à tous,

Merci pour le retour,

A tester:

=SI(NBVAL($B$33:$B$45)<=1;0;SOMME(INDIRECT("B33:B"&(EQUIV(9^9;B33:B45;1)+31))))

Cordialement,

Encore merci de prendre du temps pour m'aider, malheureusement ça ne fonctionne pas, j'ai tjs le chiffre qui s'affiche..

Bonjour,

malheureusement ça ne fonctionne pas, j'ai tjs le chiffre qui s'affiche..

Ton fichier ne semble pas correspondre avec ta demande initiale.....

Par contre j'aimerai ne cibler qu'entre les lignes 33 et 45

Cordialement,

Bonjour,

Mon fichier correspond bien à ma demande, c'st juste que mon résultat est noyé dans un tableau dans lequel je l'utilise ensuite. Bref :)

C'est parfait ça fonctionne impeccablement !!! un GRAND merci !!

et comme les choses ne sont jamais finis ! ma direction me demande de transposer mon fichier sur Sheets !!!!!!! (a moi de trouver les correspondance sur sheet maintenant!)

Encore merci pour tout!

Bonjour

Sujet déplacé sur le bon forum

Crdlt