Liens hypertextes

Bonsoir tout le monde,

J'ai un classeur 1 qui contient une feuille nommée Sommaire et un classeur 2 qui contient plusieurs feuilles.

Je veux importer toutes les noms d'onglets (feuilles) du classeur 2 dans la feuille sommaire du classeur 1 avec des liens hypertexte pour chaque feuille Via VBA.

Merci infiniment

Bonsoir xxmddxx, le forum,

Un essai.....

Je me suis aidé de l'enregistreur de macros...

Les 2 classeurs doivent être ouverts.

Private Sub CommandButton1_Click()
   Dim Colonne As Integer, ligne As Integer
   Dim wb As Workbook, f As Worksheet
    Set wb = ThisWorkbook: Set f = wb.Sheets("SOMMAIRE")

   If Not FichOuvert("Classeur2.xlsx") Then '.............................teste si fichier source ouvert
        MsgBox "Le fichier source n'est pas ouvert.": Exit Sub
   Else

    Application.ScreenUpdating = False
     Cells.ClearContents '................................................efface les données existantes
      [A1] = "SOMMAIRE DU CLASSEUR :": [A1].Font.ColorIndex = 5: [A1].Font.Size = 14: [A1].Font.Bold = True
       Colonne = 4 '......................................................colonne de départ
         ligne = 5 '......................................................ligne de départ
        For Each feuille In Workbooks("Classeur2.xlsx").Worksheets '......boucle sur les onglets du classeur 2
          f.Hyperlinks.Add Anchor:=Cells(ligne, Colonne), Address:="Classeur2.xlsx", SubAddress:="'" & feuille.Name & "'!A1", TextToDisplay:=feuille.Name
         Colonne = Colonne + 1
         If Colonne = 10 Then Colonne = 4: ligne = ligne + 2
        Next
   End If
End Sub

Function FichOuvert(f As String) As Boolean
'myDearFriend!  -  www.mdf-xlpages.com  (fonction pour tester si fichier ouvert)
    On Error Resume Next
    FichOuvert = Not Workbooks(f) Is Nothing
End Function

Cordialement,