VBA rajout d'une date lors insertion nouvelle ligne

Bonjour,

je souhaiterai savoir comment ajouter une date en bout de ma ligne copier avec vba lors de l'insertion de ma ligne dans la feuille 2 ma formule est la suivante:

Sub Reset_Ligne()

Dim c As Range, cDest As Range

Application.ScreenUpdating = False

With ThisWorkbook

'cDest: La celllule de destination: première cellule vide de la colonne A de Archivage

With .Worksheets("Archivage")

Set cDest = .Cells(.Rows.Count, "A").End(xlUp)(2)

End With

With .Worksheets("Planning")

'on cherche LA CELLULE contenant x en colonne V de Feuille Planning

Set c = .Range("V:V").Find("x", LookIn:=xlValues, lookat:=xlWhole)

If Not c Is Nothing Then

With c.EntireRow

'On copie toute la ligne trouvée vers cDest

.Copy cDest

'on supprime la ligne trouvée de Feuil1

.Delete

End With

Set c = Nothing

End If

'on vide notre variable cDest

Set cDest = Nothing

End With

End With

End Sub

Merci d'avance

Bonjour

Une version

Sub Reset_Ligne()
Dim c As Range, cDest As Range

  Application.ScreenUpdating = False
  With ThisWorkbook
    'cDest: La celllule de destination: première cellule vide de la colonne A de Archivage
    With .Worksheets("Archivage")
      Set cDest = .Cells(.Rows.Count, "A").End(xlUp)(2)
    End With
    With .Worksheets("Planning")
      'on cherche LA CELLULE contenant x en colonne V de Feuille Planning
      Set c = .Range("V:V").Find("x", LookIn:=xlValues, lookat:=xlWhole)
      If Not c Is Nothing Then
        With c.EntireRow
          'On copie toute la ligne trouvée vers cDest
          .Copy cDest
          'on supprime la ligne trouvée de Feuil1
          .Delete
          cDest.Offset(, 22) = Date   ' Juste après le x
        End With
        Set c = Nothing
      End If
      'on vide notre variable cDest
      Set cDest = Nothing
    End With

  End With
End Sub

Parfait merci pour votre réponse.