VBA * Excel envoi mails avec signature

Bonjour à tous,

j'ai un code qui fonctionne très bien pour envoyer des mails sans intégrer la signature.

Dès que j'essaie d'insérer un Display ou de faire des modifications pour intégrer la signature, j'obtiens bien ma signature, mais j'ai un seul mail avec x fois la pièce jointe, x correspondant au nombre de mails à envoyer...

Voila mon code (avec les essais):

Option Explicit

Sub STeP_CoC_Test()
    Dim Mail As Variant
    'Dim MessagingService As Object
    'Dim Mail As Object
    Dim message As String
    Dim i As Integer
    Dim Attached_document As String
    Dim Signature As String
    Set Mail = CreateObject("Outlook.Application")
    'Set MessagingService = CreateObject("Outlook.Application")
    'Set Mail = MessagingService.CreateItem(0)

       'Mail.Display
       'Signature = Mail.htmlBody

    For i = 3 To 10

        If (Cells(i, 2) = "Yes" And Cells(i, 3) = "") Then

            With Mail.CreateItem(0)
                .Subject = Range("B1")
                .To = Cells(i, 1)
                message = "Dear partner," & "<br><br>" & "In the context of blabla." & "<br><br>" & "Thank you in advance for your prompt feedback!"
                .htmlBody = message & Signature
                Attached_document = Range("D1")
                .Attachments.Add Attached_document
                .Display
                Cells(i, 3) = "Sent" & Chr(10) & Date
            End With
        End If
    Next i
Set Mail = Nothing

End Sub

J'ai essayer plusieurs choses, mais je ne trouve pas de solution...

En vous remerciant pour votre aide précieuse!

bonjour,

essaie ceci

Sub STeP_CoC_Test()
    Dim Mail As Variant
    Dim MessagingService As Object
    Dim message As String
    Dim i As Integer
    Dim Attached_document As String
    Dim Signature As String
    Set MessagingService = CreateObject("Outlook.Application")

    For i = 3 To 10
        If (Cells(i, 2) = "Yes" And Cells(i, 3) = "") Then
            With MessagingService.CreateItem(0)
                .Display
                Signature = .htmlBody
                .Subject = Range("B1")
                .To = Cells(i, 1)
                message = "Dear partner," & "<br><br>" & "In the context of blabla." & "<br><br>" & "Thank you in advance for your prompt feedback!"
                .htmlBody = message & Signature
                Attached_document = Range("D1")
                .Attachments.Add Attached_document
                .Display
                Cells(i, 3) = "Sent" & Chr(10) & Date
                '.send 'pour envoyer le mail
            End With
        End If
    Next i
    Set MessagingService = Nothing

End Sub

Ca marche nickel! En plus sans GetBoiler que je ne comprends pas vraiment pour mon niveau de débutante.

Merci d'avoir mis fin à des heures à tâtonner!

Et si rapidement!

Geniale la communauté!