Suppression nom

Bonjour,

je voudrais à partir d'une boite de dialogue supprimer le nom Boucher dans la colonne D2:D30 d'une feuille

.
Merci de bien vouloir me donner le code.

Bonsoir Novice38, le forum,

A tester...

Sub efface_nom()
 Dim plage As Range, cel As Range
 Dim nom As String

  With Sheets("Feuil1") 'nom de la feuille à adapter
   Set plage = .Range("D2:D30") 'plage à adapter
    nom = InputBox("Entrez le nom à supprimer :", "nom") 'renseigner un nom (ex:Boucher)
     If nom = "" Then Exit Sub
      Set cel = plage.Find(What:=nom)
       If cel Is Nothing Then
        MsgBox "Nom inconnu !", vbExclamation: Exit Sub
       Else
        If MsgBox("Etes-vous certain de vouloir supprimer le nom ?", vbYesNo, "Demande de confirmation") = vbYes Then
         cel.ClearContents
         MsgBox "Le nom " & nom & " a été effacé !"
       End If
     End If
  End With
End Sub

Cordialement,

Bonsoir,

super, merci beaucoup et en plus, super réactif, génial.

Bonne fin de journée;
Bien cordialement

Re,

Merci pour le retour,

Attention toutefois, si le nom est présent plusieurs fois, il n'en supprime qu'1.

Dans ce cas:

Sub efface_noms()
 Dim tb, lig%, cp%
   With Sheets("Feuil1") 'nom de la feuille à adapter
   tb = .Range("D2:D30") 'plage à adapter
   cp = 0
    nom = InputBox("Entrez le nom à supprimer :", "nom") 'renseigner un nom (ex:Boucher)
    If nom = "" Then Exit Sub
     For lig = 1 To UBound(tb, 1)
      If tb(lig, 1) Like nom Then
       cp = cp + 1
       tb(lig, 1) = ""
      End If
     Next lig
    If cp = 0 Then
     MsgBox "Nom inconnu !", vbExclamation: Erase tb: Exit Sub
    Else
     If MsgBox("Etes-vous certain de vouloir supprimer le nom  " & nom & " ?", vbYesNo, "Demande de confirmation") = vbYes Then
      .Range("D2").Resize(UBound(tb, 1), 1) = tb
       MsgBox "Le nom " & nom & " a été effacé !"
     End If
    End If
   Erase tb
  End With
End Sub

Cdlt,

Bonjour,

Merci pour la précision.

Encore merci

Bonne journée