SelectedItems en argument d'une procédure

Bonjour les amigos.

Nouveau projet.. Nouvelles galères ! mais aussi, nouvelles connaissances.

Je choisi plusieurs fichiers qui donc correspondent à

Application.FileDialog(msoFileDialogFilePicker).SelectedItems

Et j'aimerais appeller une procédure dans la quelle je pourrais utilisers tous ces fichiers, j'ai tenté ça sans succes:

(J'ai une erreur au moment d'appeller ma procédure [Argument non facultatif]

Sub Cparti()
Dim Mon_App As Workbook: Set Mon_App = ThisWorkbook
Dim i As Byte
Dim Book As String
RienChoisi:
With Application.FileDialog(msoFileDialogFilePicker)
    .AllowMultiSelect = True
    .Title = "Sélectionner des rapports de mesures"
    .Show
    Call CdesDFQ(.SelectedItems.Item, Mon_App)
End With
End Sub

Et j'ai configuré mes arguments de cette façon:

où j'espérer pouvoir utiliser DFQ(2) ou DFQ(5) voir même DFQ.count ? pour pouvoir manipuler facilement tout mes fichiers

Sub CdesDFQ(DFQ() As Workbooks, original As Workbook)
[...]
End Sub

Merki du coup de main !

A+ les loulous

Bonjour,

Je ne vois pas l'intérêt de la variable myApp, qui de plus est un choix logique ambigu car en principe elle devrait plutôt représenter l'application Excel .

ci-jointe une proposition

Sub Cparti()
    Dim booknames As New Collection
    Dim i As Integer

    With Application.FileDialog(msoFileDialogFilePicker)
        .AllowMultiSelect = True
        .Title = "Sélectionner des rapports de mesures"
        .Show
        With .SelectedItems
            For i = 1 To .Count
                booknames.Add Item:=.Item(i), Key:=CStr(i)
            Next i
        End With
        Call CdesDFQ(booknames, ThisWorkbook)
    End With

End Sub

Sub CdesDFQ(DFQ As Collection, original As Workbook)
    Dim i As Integer, bookname As String

    For i = 1 To DFQ.Count
        bookname = DFQ(i)
    Next i

End Sub

Je ne vois pas l'intérêt de la variable myApp

Moi non plus !

Salut thev, merci cela fonctionne parfaitement. Je n'avais jamais utilisé de "collection" avant.

Bonne fin de journée