Recherche de lignes

Question

Est-il possible d'avoir une macro qui puisse me donner le nombre de lignes où un des critères n'est pas présent, juste en donnant le résultat. je vous présente un exemple sur le fichier ci-joint, je vous remercie d'avance...

ThauThème · Accepted Answer

Bonjour Bastien et bienvenu, bonjour le forum,

Essaie comme ça :

Sub Macro1()
Dim O As Worksheet 'déclare la variable O (Onglet)
Dim TV As Variant 'déclare la variable TV (Tableau des Valeurs)
Dim TC As Variant 'déclare la variable TC (Tableau des Critères)
Dim Ic As Integer 'déclare la variable Ic (Incrément critère)
Dim Iv As Integer 'déclare la variable Iv (Incrément valeur)
Dim Jv As Byte 'déclare la variable Jv (incrément valeur)
Dim TEST As Boolean 'déclare la variable TEST
Dim NB As Integer 'déclare la variable NB (NomBre)

Set O = Worksheets("Feuil1") 'définit l'onglet O
TV = O.Range("A1").CurrentRegion 'définit la tableau des valeurs TV
TC = O.Range("G1").CurrentRegion 'définit la tableau des critères TC
O.Range("J1").CurrentRegion.Offset(1, 0).ClearContents 'efface les anciennes valeurs en colonne J
For Ic = 2 To UBound(TC, 1) 'boucle 1 sur toutes les lignes Ic du tableau des critères TC (en partant de la seconde)
    NB = 0: TEST = False 'réinitialise le nombre NB et le TEST
    For Iv = 2 To UBound(TV, 1) 'boucle 2 : sur toutes les lignes Iv du tableau des valeurs TV (en partant de la seconde)
        For Jv = 1 To UBound(TV, 2) 'boucle 3 : sur toutes les colonnes Jv du tableau des valeurs TV
            'définit la variable TEST (TEST est vrai si la donnée ligne Iv colonne Jv de TV est égale au critère ligne Ic colonne 1 de TC ou au critère ligne Ic colonne 2 de TC)
            TEST = IIf(TV(Iv, Jv) = TC(Ic, 1) Or TV(Iv, Jv) = TC(Ic, 2), True, False)
            If TEST = True Then Exit For 'si TEST est [Vrai] sort de la boucle 3
        Next Jv 'prochaine colonne de la boucle 3
        If TEST = False Then NB = NB + 1 'si TEST est [Faux] incrémente NB
    Next Iv
    O.Cells(Ic, "J").Value = NB 'renvoie NB dans la cellule ligne Ic, colonne J de l'onglet O
Next Ic 'prochain critère de la ligne 1
End Sub

Je n'obtiens pas le même résultat que toi mais il me semble, si j'ai bien compris ton énoncé, que le code est correct...