Produit par rapport a plafond
Voila je ne suis pas très calé en Exel, je me débrouille pour faire quelques petites choses mais la j'avoue je scotch.
En gros j'ai une Case "D3" qui me donne un nombre compris entre 0 et 15 000.
J'aimerai que dans la Case "D4" il se produise l'équivalent de ceci:
Si D3 est compris entre 0 et 5999 prendre D3 et le multiplier par 0.5
Si D3 est compris entre 6000 et 7999 prendre D3 et le multiplier par 0.6
Si D3 est compris entre 8000 et 9999 prendre D3 et le multiplier par 0.7
Si D3 est compris entre 10 000 et 15 000 prendre D3 et le multiplier par 0.8
Tout ca dans la même case, j'avoue je ne sais pas si cela est possible mais vu la puissance de se logiciel, ca doit etre faisable, a votre bon coeur pour un débutant.
Merci
Bonsoir
Par exemple:
=SI(D3>=10000;D3*0,8;SI(D3>=8000;D3*0,7;SI(D3>6000;D3*0,6;SI(D3<6000;D3*0,5))))
Cordialement,
Amadéus
Il me dis que la formule contient une erreur
Mais ca doit etre dans ce gout la je pense
Bonsoir tout le monde
une autre proposition, qui contrôle la valeur maxi
=MIN(D3;15000)*SI(D3>=10000;0,8;SI(D3>=8000;0,7;SI(D3>=6000;0,6;0,5)))
@+Jean-Marie
Toujours pas, il me dit qu'il y a une erreur je comprend pas.
Salut le forum
Essaye de remplacer les valeurs virgules(,) par des points(.) dans les nombres
0,8 devient 0.8
0,7 devient 0.7
Mytå
Toujours pas je desepere
Merci en tout cas de vous pencher sur mon cas
Salut le forum
Un fichier https://www.excel-pratique.com/~files/doc/Canard.xls avec les
formules qui fonctionne bien.
Mytå
Bonjour,
Trois autres possibilités (sans SI et sans décimales) :
=((D3<15000)*8-(D3<10000)-(D3<8000)-(D3<6000))/10*D3
=CHOISIR((D3>0)+(D3>6000)+(D3>8000)+(D3>10000);5;6;7;8 )/10*D3
supprimer l'espace entre 8 )
=RECHERCHEV(D3;{0\5;6000\6;8000\7;10000\8};2)/10*D3
Bonjour
Avant de faire une encyclopédie de formules conditionnelles, il serai bon que notre ami nous indique la formule en D3, ou nous envoie son fichier.
Car pour que plein de formules éprouvées ne marchent pas, je demande à voir.
Cordialement,
Amadéus a écrit :il serai bon que notre ami nous indique la formule en D3, ou nous envoie son fichier.
Ce serait je pense la solution idéale, ne serait-ce que pour voir le format des nombres employés ; Joindre un fichier est en haut de page, n'oublie pas de copier/coller le lien donné dans ta réponse.
A +