Ne selectionner qu'une cellule sur 2
Bonjour à tous, voici mon problème:
j'ai importé un très grand nombre de données sur excel (sur plusieurs onglets) et notamment des données chiffrées. J'aurais besoin de faire des moyennes, des sommes sur ces données, mais le cas par cas serait bcp trop long.
Aussi, j'aurais souhaité savoir s'il était possible à l'aide d'une macro (ou pas) de ne selectionner par exemple qu'une ligne sur deux (ou sur 3, 4...) ou bien alors de ne sommer qu'une ligne sur 2...
Ds l'exemple que je vous joins, je souhaiterais ne selectionner qu'une cellule sur 4 pour chaque colonne (celle où il y a la valeur).
En vous remerciant par avance.
https://www.excel-pratique.com/~files/doc/sulWm1lignesur2.xls
Bonjour
Dans le cas présent, il s'agit de faire la moyenne des valeurs "Open"
Pas besoin de macro, avec Sommeprod (ou Somme.Si) et NB.SI, on atteint le résultat.
1) Sommes (Une des solutions possibles)
Exemple pour colonne B:
=SOMME.SI($A$1:$A$595;"Open";$B$1:$B$595) qui donne 11659,746
=SOMMEPROD(($A$1:$A$595="Open")*($B$1:$B$595)) (Ne fonctionnera que lorsque la liaison col B sera rétablie)
de même, pour colonne C:
=SOMMEPROD(($A$1:$A$595="Open")*($C$1:$C$595)) ou
=SOMME.SI($A$1:$A$595;"Open";$C$1:$C$595) qui donnent 11440,745
2) Moyenne (Une des solutions possibles)
NB.SI donne le nombre de valeurs Ex NB.SI($A$1:$A$595;"Open") donne le nb de valeurs "Open"
La Moyenne est obtenue par
=SOMMEPROD(($A$1:$A$595="Open")*($B$1:$B$595))/NB.SI($A$1:$A$595;"Open")
ou
=SOMME.SI($A$1:$A$595;"Open";$B$1:$B$595)/NB.SI($A$1:$A$595;"Open") en colonne B
(Nul doute que dre passant par là trouvera autre chose)
Cordialement
Bonjour Vidal, salut Amadeus,
J'ai pris la question au pied de la lettre, ne me basant que sur la position des valeurs à additionner, c'est à dire toutes les quatre lignes à partir de la troisième.
Le fait que dans l'exemple les cellules concernées se trouvent toujours à côté du "Open" pourrait n'être qu'un hasard.
Ce qui pose problème ce sont les messages d'erreurs : #NOM?
En établissant la liaison avec l'autre classeur elles seront remplacées par une date, une espace, VRAI, ... et dès lors la formules suivante fonctionne aussi (je l'ai testée sur les 24 premières lignes) :
=SOMMEPROD((MOD(LIGNE(B1:B595)+1;4)=0)*1;B1:B595)
Pour la colonne C j'obtiens également 11440.7455
dré
Bonjour dre
Le fait que dans l'exemple les cellules concernées se trouvent toujours à côté du "Open" pourrait n'être qu'un hasard
Ouais! Bien sur..Toujours aussi roublard! Pas pousser quand même...
Impec ta formule..
Amicalement
Merci bcp à vous 2 . Dre je n'avais même pas pensé au biais qu'occasionné "open", donc bien joué. J'arrive à me servir de ta formule mais quant à comprendre comment elle fonctionne, c'est une autre histoire.
Bonjour,
Ce n'est pas moi mais bien Amadeus qui a "repéré" la liaison possible avec la valeur "Open".
Quand à la formule que je t'ai proposée :
=SOMMEPROD((MOD(LIGNE(B1:B595)+1;4)=0)*1;B1:B595)
Dans une colonne quelconque en ligne 1 la formule :
MOD(LIGNE()+1;4)=0
renvoie VRAI ou FAUX et tu constateras que les VRAI se situent toutes les 4 lignes à partir de la 3ème, parce que le reste de la division (3+1)/4 ou (7+1)/4 ou (11+1)/4 égale 0
On multiplie ce résultat par 1 pour que VRAI devienne 1 et FAUX devienne 0.
On multiplie ce résultat (1 ou 0) par la colonne B et on additionne les résultats, de là le nom de la fonction matricielle : la somme des produits.
dré