Modifier la sélection automatique des cellules dans Excel
Bonjour à tous,
Comment peut on décaler la sélection automatique des cellules dans Excel ?
Je m'explique : J'ai un calcul qui comprend 2 cellules sources dans une plage de données issue de la feuille "Planning_Général". Le résultat de ce calcul s'affiche dans une cellule de la feuille "Tableau". Je souhaite automatiser cette opération pour les cellules allant de B3 jusqu'à H3 de la feuille "Tableau". Mon problème est que la sélection automatique d'Excel avance d'une cellule à chaque fois.
Est-il possible d'avancer de 2 cellules au lieu d'1 de manière automatique ?
Dans le document ci joint il y a : Tableau!B3 = Planning_Général!O14 - Planning_Général!N14
Comment faire pour que Tableau!C3=Planning_Général!Q14-Planning_Général!P14 au lieu de Planning_Général!P14-Planning_Général!O14 ?
et Tableau!D3 = Planning_Général!S14-Planning_Général!R14 au lieu de Planning_Général!R14-Planning_Général!Q14 et ainsi de suite, sans que j'ai besoin de préciser le décalager dans chaque cellule de la feuille "Tableau" ?
Merci beaucoup pour votre aide.
Bonjour
En B3 à recopier à droite et en dessous
=SI(INDIRECT("Planning_Général!L"&LIGNE(B14)&"C"&COLONNE($N3)+(COLONNE()-2)*2;0)<24;
INDIRECT("Planning_Général!L"&LIGNE(B14)&"C"&COLONNE($O3)+(COLONNE()-2)*2;0)-INDIRECT("Planning_Général!L"&LIGNE(B14)&"C"&COLONNE($N3)+(COLONNE()-2)*2;0);
INDIRECT("Planning_Général!L"&LIGNE(B14)&"C"&COLONNE($N3)+(COLONNE()-2)*2;0))Merci beaucoup Chris, on a l'air d'être sur la bonne voie.
Comme je suis débutant, je ne comprends pas trop la formule sur certains points et je vais devoir l'adapter sur plusieurs tableaux.
Peux tu me dire à quoi correspondent les colonnes et le *2 indiqués en bleu ?
=SI(INDIRECT("Planning_Général!L"&LIGNE(B14)&"C"&COLONNE($N3)+(COLONNE()-2)*2;0)<24;
INDIRECT("Planning_Général!L"&LIGNE(B14)&"C"&COLONNE($O3)+(COLONNE()-2)*2;0)-INDIRECT("Planning_Général!L"&LIGNE(B14)&"C"&COLONNE($N3)+(COLONNE()-2)*2;0);
INDIRECT("Planning_Général!L"&LIGNE(B14)&"C"&COLONNE($N3)+(COLONNE()-2)*2;0))
Merci à toi d'avoir passé du temps sur mon problème.
RE
c'est justement pour se décaler de 2 en 2
en B, COLONNE() donne 2 donc pour démarrer à 0, soit ne pas se décaler par rapport à $N3 : COLONNE()-2
en C, COLONNE()-2 donne 1 qu'on multiplie par 2 pour se décaler en P3 et non en O3
RE
Parce que dans le planning le 6/01 est en N3 (N pour la date et 3 pour la personne) et que ton tableau commence au 6/01
N est figé comme point à partir duquel on se déplace de 2 en 2 et non de 1 en 1 comme tu le demandais
RE
Oui effectivement j'ai répondu trop vite : le 3 n'a aucune importance ici c'est N qui importe puisque N3 ou N1000 renvoient le même numéro de colonne qui lui nous intéresse
D'accord, mais comme je débute, je n'arrive pas à comprendre la formule.
j'ai ajouté un second tableau sur la feuille Tableau, pourrais tu adapter cette formule au 2eme tableau juste pour la personne HECTOR ?
Je me dis qu'en voyant les différences entre le tableau1 et le tableau2, j'arriverai à comprendre la formule et à l'adapter par la suite.
Merci encore pour ta patience.
RE
La seule chose qui change est que le 1 février est en BN et non N
Donc
=SI(INDIRECT("Planning_Général!L"&LIGNE(B14)&"C"&COLONNE($BN3)+(COLONNE()-2)*2;0)<24;
INDIRECT("Planning_Général!L"&LIGNE(B14)&"C"&COLONNE($BO3)+(COLONNE()-2)*2;0)-INDIRECT("Planning_Général!L"&LIGNE(B14)&"C"&COLONNE($BN3)+(COLONNE()-2)*2;0);
INDIRECT("Planning_Général!L"&LIGNE(B14)&"C"&COLONNE($BN3)+(COLONNE()-2)*2;0))Et donc on utilise BN et BO au lieu de N et O
Super, ça fonctionne nikel !
Merci beaucoup !!
Pour que j'essaie de comprendre, peux tu me dire à quoi correspond le L en bleu bleu dans la formule ?
=SI(INDIRECT("Planning_Général!L"&LIGNE(B14)&"C"&COLONNE($BN3)+(COLONNE()-2)*2;0)<24;
RE
INDIRECT permet de construire des adresses
- soit on utilise le type A1 mais cela est inutilement compliqué à rendre variable avec les lettres, pour ajouter 2 colonnes à A notament
- soit on utilise la notation L1C1, ou L signifie Ligne et C colonne, ou il est facile d'ajouter 2 à 1
N'hésites à consulter l'aide en ligne sur les fonctions et à te faire un croquis pour matérialiser et comprendre ce qui se passe d'une colonne à l'autre avec la même formule
Oui j'ai commencé à regarder, c'est top !
Merci encore en tout cas, c'est vraiment chouette d'avoir un coup de main de gens qui s'y connaissent
Bonne journée à toi et à la prochaine peut être.